//SINGULAR Example 1.1.8



ring A = 0,x,dp;
number n = 12345/6789;
n^5;                    //common divisors are cancelled

ring A1 = 32003,x,dp;   //finite field Z/32003 
number(123456789)^5;

ring A2 = (2^3,a),x,dp; //finite (Galois) field GF(8) 
                        //with 8 elements
number n = a+a2;        //a is a generator of the group
                        //GF(8)-{0}
n^5;            

minpoly;                //minimal polynomial of GF(8)

ring A3 = (2,a),x,dp;   //infinite field Z/2(a) of 
                        //characteristic 2
minpoly = a20+a3+1;     //define a minimal polynomial
                        //a^20+a^3+1
                        //now the ground field is
                        //GF(2^20)=Z/2[a]/<a^20+a^3+1>, 
number n = a+a2;        //a finite field 
                        //with 2^20 elements
n^5;                    //a is a generator of the group 
                        //GF(2^20)-{0}

ring tst = 2,a,dp;
factorize(a20+a2+1,1);          

factorize(a20+a3+1,1);   //irreducible

ring R1 = (real,30),x,dp;
number n = 123456789.0;
n^5;             //compute with a precision of 30 digits



ring R2 = (complex,30,I),x,dp;//I denotes imaginary unit
number n = 123456789.0+0.0001*I;
n^5;            //complex number with 30 digits precision

ring R3 = (0,a,b,c),x,dp;
number n = 12345a+12345/(78bc);
n^2;
n/9c;