Top
Back: Rings and orderings
Forward: General syntax of a ring declaration
FastBack: Emacs user interface
FastForward: Implemented algorithms
Up: Rings and orderings
Top: Singular Manual
Contents: Table of Contents
Index: Index
About: About this document

3.3.1 Examples of ring declarations

The exact syntax of a ring declaration is given in the next two subsections; this subsection lists some examples first. Note that the chosen ordering implies that a unit-elements of the ring will be among the elements with leading monomial 1. For more information, see Monomial orderings.

Every floating point number in a ring consists of two parts, which may be chosen by the user. The leading part represents the number and the rest is for numerical stability. Two numbers with a difference only in the rest will be regarded equal.

  • the ring $Z/32003[x,y,z]$ with degree reverse lexicographical ordering. The exact ring declaration may be omitted in the first example since this is the default ring:

     
    ring r1;
    ring r2 = 32003,(x,y,z),dp;
    ring r3=(ZZ/32003)[x,y,z];
    ring r4 = (ZZ/32003),(x,y,z),dp;
    

  • similar examples with indexed variables. The ring variables of r1 are going to be x(1)..x(10); in r2 they will be x(1)(1), x(1)(2), ..., x(1)(8), x(2)(1), ..., x(5)(8):

     
    ring r1 = 32003,(x(1..10)),dp;
    ring r2 = 32003,(x(1..5)(1..8)),dp;
    ring r3 = (ZZ/32003)[x(1..5)(1..8)];
    ring r4 = (ZZ/32003),(x(1..5)(1..8)),dp;
    

  • the ring $Q[a,b,c,d]$ with lexicographical ordering:

     
    ring r1 = 0,(a,b,c,d),lp;
    ring r2 = QQ,(a,b,c,d),lp;
    

  • the ring $Z/7[x,y,z]$ with local degree reverse lexicographical ordering. The non-prime 10 is converted to the next lower prime in the second example:

     
    ring r1 = 7,(x,y,z),ds;
    ring r2 = 10,(x,y,z),ds;
    ring r3 = (ZZ/7),(x,y,z),ds;
    

  • the ring $Z/7[x_1,\ldots,x_6]$with lexicographical ordering for $x_1,x_2,x_3$and degree reverse lexicographical ordering for $x_4,x_5,x_6$:

     
    ring r1 = 7,(x(1..6)),(lp(3),dp);
    ring r2 = (ZZ/7),(x(1..6)),(lp(3),dp);
    

  • the localization of $(Q[a,b,c])[x,y,z]$ at the maximal ideal

    $(x,y,z)$:

     
    ring r1 = 0,(x,y,z,a,b,c),(ds(3), dp(3));
    ring r2 = QQ,(x,y,z,a,b,c),(ds(3), dp(3));
    

  • the ring $Q[x,y,z]$ with weighted reverse lexicographical ordering. The variables $x$, $y$, and $z$ have the weights 2, 1, and 3, respectively, and vectors are first ordered by components (in descending order) and then by monomials:
     
    ring r1 = 0,(x,y,z),(c,wp(2,1,3));
    ring r2 = QQ,(x,y,z),(c,wp(2,1,3));
    
    For ascending component order, the component ordering C has to be used.

  • the ring $K[x,y,z]$, where $K=Z/7(a,b,c)$ denotes the transcendental extension of $Z/7$ by $a$, $b$ and $c$ with degree lexicographical ordering:

     
    ring r = (7,a,b,c),(x,y,z),Dp;
    

  • the ring $K[x,y,z]$, where $K=Z/7[a]$ denotes the algebraic extension of degree 2 of $Z/7$ by $a.$ In other words, $K$ is the finite field with 49 elements. In the first case, $a$ denotes an algebraic element over $Z/7$ with minimal polynomial $\mu_a=a^2+a+3$,in the second case, $a$

    refers to some generator of the cyclic group of units of $K$:

     
    ring r = (7,a),(x,y,z),dp; minpoly = a^2+a+3;
    ring r = (7^2,a),(x,y,z),dp;
    

  • the ring $R[x,y,z]$, where $R$ denotes the field of real numbers represented by simple precision floating point numbers. This is a special case:

     
    ring r = real,(x,y,z),dp;
    

  • the ring $R[x,y,z]$, where $R$ denotes the field of real numbers represented by floating point numbers of 50 valid decimal digits and the same number of digits for the rest:

     
    ring r = (real,50),(x,y,z),dp;
    

  • the ring $R[x,y,z]$, where $R$ denotes the field of real numbers represented by floating point numbers of 10 valid decimal digits and with 50 digits for the rest:

     
    ring r = (real,10,50),(x,y,z),dp;
    

  • the ring $R(j)[x,y,z]$, where $R$ denotes the field of real numbers represented by floating point numbers of 30 valid decimal digits and the same number for the rest. $j$ denotes the imaginary unit.

     
    ring r = (complex,30,j),(x,y,z),dp;
    

  • the ring $R(i)[x,y,z]$, where $R$ denotes the field of real numbers represented by floating point numbers of 6 valid decimal digits and the same number for the rest. $i$ is the default for the imaginary unit.

     
    ring r = complex,(x,y,z),dp;
    

  • the quotient ring $Z/7[x,y,z]$ modulo the square of the maximal ideal $(x,y,z)$:

     
    ring R = 7,(x,y,z), dp;
    qring r = std(maxideal(2));
    

  • the ring $Z[x,y,z]$:

     
    ring R = integer,(x,y,z), dp;
    

  • the ring $Z/6^3[x,y,z]$:

     
    ring R = (integer, 6, 3),(x,y,z), dp;
    

  • the ring $Z/100[x,y,z]$:

     
    ring R = (integer, 100),(x,y,z), dp;
    


Top Back: Rings and orderings Forward: General syntax of a ring declaration FastBack: Emacs user interface FastForward: Implemented algorithms Up: Rings and orderings Top: Singular Manual Contents: Table of Contents Index: Index About: About this document
            User manual for Singular version 4.3.2, 2023, generated by texi2html.