source: git/Singular/grammar.y @ d51fb30

fieker-DuValspielwiese
Last change on this file since d51fb30 was 4c001a, checked in by Olaf Bachmann <obachman@…>, 27 years ago
Merged fixes from 1-0-0 release git-svn-id: file:///usr/local/Singular/svn/trunk@358 2c84dea3-7e68-4137-9b89-c4e89433aadc
  • Property mode set to 100644
File size: 40.5 KB
Line 
1/****************************************
2*  Computer Algebra System SINGULAR     *
3****************************************/
4/* $Id: grammar.y,v 1.10 1997-06-04 19:45:14 obachman Exp $ */
5/*
6* ABSTRACT: SINGULAR shell grammatik
7*/
8%{
9
10#include <stdio.h>
11#include <stddef.h>
12#include <stdlib.h>
13#include <stdarg.h>
14#include <string.h>
15#include <limits.h>
16
17#include "mod2.h"
18#include "tok.h"
19#include "stype.h"
20#include "ipid.h"
21#include "intvec.h"
22#include "febase.h"
23#include "matpol.h"
24#include "ring.h"
25#include "kstd1.h"
26#include "mmemory.h"
27#include "subexpr.h"
28#include "ipshell.h"
29#include "ipconv.h"
30#include "ideals.h"
31#include "numbers.h"
32#include "polys.h"
33#include "weight.h"
34#include "stairc.h"
35#include "timer.h"
36#include "cntrlc.h"
37#include "maps.h"
38#include "syz.h"
39#include "lists.h"
40
41
42extern int   yylineno;
43extern FILE* yyin;
44
45char       my_yylinebuf[YY_READ_BUF_SIZE];
46char *     currid;
47BOOLEAN    noringvars=FALSE;
48BOOLEAN    expected_parms;
49int        cmdtok;
50int        inerror = 0;
51
52#define TESTSETINT(a,i)                                \
53   if ((a).Typ() != INT_CMD)                           \
54   {                                                   \
55     WerrorS("no int expression");                     \
56     YYERROR;                                          \
57   }                                                   \
58   (i) = (int)(a).Data();
59
60#define MYYERROR(a) { WerrorS(a); YYERROR; }
61
62void yyerror(char * fmt)
63{
64  int oldInError=inerror;
65
66  inerror = 1;
67  BOOLEAN old_errorreported=errorreported;
68  errorreported = TRUE;
69  if (currid!=NULL)
70  {
71    killid(currid,&idroot);
72    currid = NULL;
73  }
74  if(!oldInError)
75  {
76    Werror( "error occurred in %s line %d: `%s`"
77           ,VoiceName(), yylineno-1, my_yylinebuf);
78    if (cmdtok!=0)
79    {
80      char *s=Tok2Cmdname(cmdtok);
81      if (expected_parms)
82      {
83        Werror("expected %s-expression. type \'help %s;\'",s,s);
84      }
85      else
86      {
87        Werror("wrong type declaration. type \'help %s;\'",s);
88      }
89    }
90    if (!old_errorreported && (lastreserved!=NULL))
91    {
92      Werror("last reserved name was `%s`",lastreserved);
93    }
94  }
95  else
96    inerror=oldInError;
97  if ((voice>0)&&(myynest>0))
98  {
99    Werror("leaving %s",VoiceName());
100    exitBuffer(BT_proc);
101  }
102}
103
104#ifndef alloca
105#define alloca malloc
106#endif
107
108%}
109
110/* %expect 22 */
111%pure_parser
112
113/* special symbols */
114%token DOTDOT
115%token EQUAL_EQUAL
116%token GE
117%token LE
118/*%token MINUSEQUAL*/
119%token MINUSMINUS
120%token NOT
121%token NOTEQUAL
122/*%token PLUSEQUAL*/
123%token PLUSPLUS
124
125/* types, part 1 (ring indep.)*/
126%token <i> DRING_CMD
127%token <i> INTMAT_CMD
128%token <i> PROC_CMD
129%token <i> RING_CMD
130
131/* valid when ring defined ! */
132%token <i> BEGIN_RING
133/* types, part 2 */
134%token <i> IDEAL_CMD
135%token <i> MAP_CMD
136%token <i> MATRIX_CMD
137%token <i> MODUL_CMD
138%token <i> NUMBER_CMD
139%token <i> POLY_CMD
140%token <i> VECTOR_CMD
141/* end types */
142
143/* ring dependent cmd:*/
144%token <i> BAREISS_CMD
145%token <i> BETTI_CMD
146%token <i> COEFFS_CMD
147%token <i> COEF_CMD
148%token <i> CONTRACT_CMD
149%token <i> DEGREE_CMD
150%token <i> DEG_CMD
151%token <i> DIFF_CMD
152%token <i> DIM_CMD
153%token <i> ELIMINATION_CMD
154%token <i> E_CMD
155%token <i> FETCH_CMD
156%token <i> FREEMODULE_CMD
157%token <i> KEEPRING_CMD
158%token <i> HILBERT_CMD
159%token <i> HOMOG_CMD
160%token <i> IMAP_CMD
161%token <i> INDEPSET_CMD
162%token <i> INTERRED_CMD
163%token <i> INTERSECT_CMD
164%token <i> JACOB_CMD
165%token <i> JET_CMD
166%token <i> KBASE_CMD
167%token <i> KOSZUL_CMD
168%token <i> LEADCOEF_CMD
169%token <i> LEADEXP_CMD
170%token <i> LEAD_CMD
171%token <i> LIFTSTD_CMD
172%token <i> LIFT_CMD
173%token <i> MAXID_CMD
174%token <i> MINBASE_CMD
175%token <i> MINOR_CMD
176%token <i> MINRES_CMD
177%token <i> MODULO_CMD
178%token <i> MRES_CMD
179%token <i> MULTIPLICITY_CMD
180%token <i> ORD_CMD
181%token <i> PAR_CMD
182%token <i> PARDEG_CMD
183%token <i> PREIMAGE_CMD
184%token <i> QUOTIENT_CMD
185%token <i> QHWEIGHT_CMD
186%token <i> REDUCE_CMD
187%token <i> REGULARITY_CMD
188%token <i> RES_CMD
189%token <i> SIMPLIFY_CMD
190%token <i> SORTVEC_CMD
191%token <i> SRES_CMD
192%token <i> STD_CMD
193%token <i> SUBST_CMD
194%token <i> SYZYGY_CMD
195%token <i> VAR_CMD
196%token <i> VDIM_CMD
197%token <i> WEDGE_CMD
198%token <i> WEIGHT_CMD
199
200/*system variables in ring block*/
201%token <i> VALTVARS
202%token <i> VMAXDEG
203%token <i> VMAXMULT
204%token <i> VNOETHER
205%token <i> VMINPOLY
206
207%token <i> END_RING
208/* end of ring definitions */
209
210%token <i> CMD_1
211%token <i> CMD_2
212%token <i> CMD_3
213%token <i> CMD_12
214%token <i> CMD_23
215%token <i> CMD_123
216%token <i> CMD_M
217%token <i> ROOT_DECL
218        /* put variables of this type into the idroot list */
219%token <i> ROOT_DECL_LIST
220        /* put variables of this type into the idroot list */
221%token <i> RING_DECL
222        /* put variables of this type into the currRing list */
223%token <i> EXAMPLE_CMD
224%token <i> EXECUTE_CMD
225%token <i> EXPORT_CMD
226%token <i> HELP_CMD
227%token <i> KILL_CMD
228%token <i> LIB_CMD
229%token <i> LISTVAR_CMD
230%token <i> SETRING_CMD
231%token <i> TYPE_CMD
232
233%token <name> STRINGTOK BLOCKTOK INT_CONST
234%token <name> UNKNOWN_IDENT RINGVAR PROC_DEF
235
236/* control */
237%token <i> BREAK_CMD
238%token <i> CONTINUE_CMD
239%token <i> ELSE_CMD
240%token <i> EVAL
241%token <i> QUOTE
242%token <i> FOR_CMD
243%token <i> IF_CMD
244%token <i> SYS_BREAK
245%token <i> WHILE_CMD
246%token <i> RETURN
247%token <i> END_PROC
248%token <i> PARAMETER
249
250/* system variables */
251%token <i> SYSVAR
252
253%type <name> extendedid
254%type <lv>   rlist ordering OrderingList orderelem
255%type <name> stringexpr
256%type <lv>   expr elemexpr exprlist expr_arithmetic
257%type <lv>   declare_ip_variable left_value
258%type <i>    ordername
259%type <i>    cmdeq
260%type <i>    currring_lists
261%type <i>    setrings
262%type <i>    ringcmd1
263
264%type <i>    '=' '<' '>' '+' '-'
265%type <i>    '*' '/' '[' ']' '.' '^' ',' ';'
266
267
268/*%nonassoc '=' PLUSEQUAL DOTDOT*/
269%nonassoc '=' DOTDOT
270%left '|' '&'
271%left EQUAL_EQUAL NOTEQUAL
272%left '<' '>' GE LE
273%left '+' '-'
274%left '*' '/' '%'
275%left UMINUS
276%left  '^'
277%left '[' ']'
278%left '(' ')'
279%left PLUSPLUS
280%left MINUSMINUS
281
282%%
283lines:
284        /**/
285        | lines pprompt
286          {
287            if (timerv
288            #ifdef SIC
289            && (!sic)
290            #endif
291            )
292            {
293              writeTime("used time:");
294              startTimer();
295            }
296            #ifdef HAVE_RTIMER
297            if (rtimerv
298            #ifdef SIC
299            && (!sic)
300            #endif
301            )
302            {
303              writeRTime("used real time:");
304              startRTimer();
305            }
306            #endif
307            prompt_char = '>';
308            currid = NULL;
309            if (errorreported)
310            {
311              yyerror("");
312            }
313            if (inerror==2) PrintLn();
314            errorreported = inerror = cmdtok = 0;
315            lastreserved=NULL;
316            expected_parms=FALSE;
317            noringvars = FALSE;
318            test_int();
319          }
320        ;
321
322pprompt:
323        flowctrl                       /* if, while, for etc */
324        | command ';'                  /* commands returning no value */
325          {ifswitch[voice]=0;}
326        | assign  ';'                  /* general assignment */
327          {ifswitch[voice]=0;}
328        | parametercmd ';'             /* proc parameter assignments */
329          {yylineno--;ifswitch[voice]=0;}
330        | declare_ip_variable ';'      /* default initialization */
331          { $1.CleanUp(); ifswitch[voice]=0;}
332        | filecmd
333          {ifswitch[voice]=0;}
334        | returncmd
335          {
336            #ifdef SIC
337            if (!sic)
338            #endif
339            YYACCEPT;
340          }
341        | SYS_BREAK
342          {
343            #ifdef SIC
344            if (sic)
345              emStoreOp(SYS_BREAK,0);
346            else
347            #endif
348            {
349              ifswitch[voice]=0;
350              iiDebug();
351            }
352          }
353        | ';'                    /* ignore empty statements */
354          {ifswitch[voice]=0;}
355        | error ';'
356          {
357            #ifdef SIQ
358            siq=0;
359            #endif
360            ifswitch[voice]=0;
361            if (inerror&&($1.i<UMINUS) && ($1.i>' '))
362            {
363              // 1: yyerror called
364              // 2: scanner put actual string
365              // 3: error rule put token+\n
366              inerror=3;
367              Print(" error at token `%s`\n",iiTwoOps($1.i));
368            }
369            if (!errorreported) WerrorS("...parse error");
370            yyerror("");
371            yyerrok;
372            #ifdef SIC
373            if (sic) YYABORT;
374            #endif
375            if (myynest>0)
376            {
377              //WerrorS("leaving yyparse");
378              YYABORT;
379            }
380            else if (voice>0)
381            {
382              //WerrorS("leaving voice");
383              exitBuffer(BT_break);
384            }
385            errorreported = FALSE;
386            lastreserved=NULL;
387          }
388        ;
389
390flowctrl: ifcmd
391          | whilecmd
392          | forcmd
393          | proccmd
394            {ifswitch[voice]=0;}
395        ;
396
397command: executecmd | helpcmd | killcmd | exportcmd | listcmd
398         | ringcmd | scriptcmd | setringcmd | typecmd
399         ;
400
401assign: left_value exprlist
402          {
403            if(iiAssign(&$1,&$2)) YYERROR;
404          }
405        ;
406
407elemexpr:
408        RINGVAR
409          {
410            #ifdef SIC
411            if (!sic)
412            #endif
413              if (currRing==NULL) MYYERROR("no ring active");
414            syMake(&$$,$1);
415          }
416        | extendedid
417          {
418            syMake(&$$,$1);
419          }
420        | elemexpr '('  ')'
421          {
422            if(iiExprArith1(&$$,&$1,'(')) YYERROR;
423          }
424        | elemexpr '(' exprlist ')'
425          {
426            $1.next=(leftv)Alloc(sizeof(sleftv));
427            memcpy($1.next,&$3,sizeof(sleftv));
428            if(iiExprArithM(&$$,&$1,'(')) YYERROR;
429          }
430        | elemexpr '.' extendedid
431          {
432            idhdl r=idroot;
433            if ($1.Typ()!=PACKAGE_CMD) MYYERROR("<package>.<id> expected");
434            idroot=IDPACKAGE((idhdl)$1.data)->idroot;
435            syMake(&$$,$3);
436            idroot=r;
437          }
438        | '[' exprlist ']'
439          {
440            if (currRingHdl==NULL) MYYERROR("no ring active");
441            int j = 0;
442            memset(&$$,0,sizeof(sleftv));
443            $$.rtyp=VECTOR_CMD;
444            leftv v = &$2;
445            while (v!=NULL)
446            {
447              poly p = pOne();
448              pSetCompP(p,++j);
449              int k = (int)(v->Data());
450              if (k!=0)
451              {
452                if (v->Typ() == INT_CMD)
453                {
454                  $$.data = (void *)pAdd((poly)$$.data,pMult(p,pISet(k)));
455                }
456                else if (v->Typ() == POLY_CMD)
457                {
458                  $$.data = (void *)pAdd((poly)$$.data,pMult(p, (poly)(v->CopyD())) );
459                }
460                else
461                  MYYERROR("expected '[poly,...'");
462              }
463              else
464                pDelete1(&p);
465              v=v->next;
466            }
467            $2.CleanUp();
468          }
469        | INT_CONST
470          {
471            memset(&$$,0,sizeof($$));
472            int i = atoi($1);
473
474            /* check: out of range input */
475            int l = strlen($1)+2;
476            if (l >= MAX_INT_LEN)
477            {
478              char tmp[100];
479              sprintf(tmp,"%d",i);
480              if (strcmp(tmp,$1)!=0)
481              {
482                Werror("`%s` greater than %d(max. integer representation)"
483                       ,$1,INT_MAX);
484                YYERROR;
485              }
486            }
487            /*remember not to FreeL($1)
488            *because it is a part of the scanner buffer*/
489            $$.rtyp  = INT_CMD;
490            $$.data = (void *)i;
491          }
492        | SYSVAR
493          {
494            memset(&$$,0,sizeof($$));
495            $$.rtyp = $1;
496            $$.data = $$.Data();
497          }
498        | stringexpr
499          {
500            memset(&$$,0,sizeof($$));
501            $$.rtyp  = STRING_CMD;
502            $$.data = $1;
503          }
504        ;
505
506exprlist:
507        expr ',' exprlist
508          {
509            leftv v = &$1;
510            while (v->next!=NULL)
511            {
512              v=v->next;
513            }
514            v->next = (leftv)Alloc(sizeof(sleftv));
515            memcpy(v->next,&($3),sizeof(sleftv));
516            $$ = $1;
517          }
518        | expr
519          {
520            $$ = $1;
521          }
522        | '(' expr ',' exprlist ')'
523          {
524            leftv v = &$2;
525            while (v->next!=NULL)
526            {
527              v=v->next;
528            }
529            v->next = (leftv)Alloc(sizeof(sleftv));
530            memcpy(v->next,&($4),sizeof(sleftv));
531            $$ = $2;
532          }
533        ;
534
535expr:   expr_arithmetic
536          {
537            /*if ($1.typ == eunknown) YYERROR;*/
538            $$ = $1;
539          }
540        | elemexpr        { $$ = $1; }
541        | '(' expr ')'    { $$ = $2; }
542        | expr '[' expr ',' expr ']'
543          {
544            if(iiExprArith3(&$$,'[',&$1,&$3,&$5)) YYERROR;
545          }
546        | expr '[' expr ']'
547          {
548            if(iiExprArith2(&$$,&$1,'[',&$3)) YYERROR;
549          }
550        | ROOT_DECL '(' expr ')'
551          {
552            if(iiExprArith1(&$$,&$3,$1)) YYERROR;
553          }
554        | ROOT_DECL_LIST '(' exprlist ')'
555          {
556            if(iiExprArithM(&$$,&$3,$1)) YYERROR;
557          }
558        | ROOT_DECL_LIST '(' ')'
559          {
560            if(iiExprArithM(&$$,NULL,$1)) YYERROR;
561          }
562        | RING_DECL '(' expr ')'
563          {
564            if(iiExprArith1(&$$,&$3,$1)) YYERROR;
565          }
566        | currring_lists '(' exprlist ')'
567          {
568            if(iiExprArithM(&$$,&$3,$1)) YYERROR;
569          }
570        | currring_lists '(' ')'
571          {
572            if(iiExprArithM(&$$,NULL,$1)) YYERROR;
573          }
574        | CMD_1 '(' expr ')'
575          {
576            if(iiExprArith1(&$$,&$3,$1)) YYERROR;
577          }
578        | CMD_2 '(' expr ',' expr ')'
579          {
580            if(iiExprArith2(&$$,&$3,$1,&$5,TRUE)) YYERROR;
581          }
582        | CMD_3 '(' expr ',' expr ',' expr ')'
583          {
584            if(iiExprArith3(&$$,$1,&$3,&$5,&$7)) YYERROR;
585          }
586        | CMD_M '(' ')'
587          {
588            if(iiExprArithM(&$$,NULL,$1)) YYERROR;
589          }
590        | CMD_23 '(' expr ',' expr ')'
591          {
592            if(iiExprArith2(&$$,&$3,$1,&$5,TRUE)) YYERROR;
593          }
594        | CMD_23 '(' expr ',' expr ',' expr ')'
595          {
596            if(iiExprArith3(&$$,$1,&$3,&$5,&$7)) YYERROR;
597          }
598        | CMD_12 '(' expr ')'
599          {
600            if(iiExprArith1(&$$,&$3,$1)) YYERROR;
601          }
602        | CMD_12 '(' expr ',' expr ')'
603          {
604            if(iiExprArith2(&$$,&$3,$1,&$5,TRUE)) YYERROR;
605          }
606        | CMD_123 '(' expr ')'
607          {
608            if(iiExprArith1(&$$,&$3,$1)) YYERROR;
609          }
610        | CMD_123 '(' expr ',' expr ')'
611          {
612            if(iiExprArith2(&$$,&$3,$1,&$5,TRUE)) YYERROR;
613          }
614        | CMD_123 '(' expr ',' expr ',' expr ')'
615          {
616            if(iiExprArith3(&$$,$1,&$3,&$5,&$7)) YYERROR;
617          }
618        | MATRIX_CMD '(' expr ',' expr ',' expr ')'
619          {
620            if(iiExprArith3(&$$,MATRIX_CMD,&$3,&$5,&$7)) YYERROR;
621          }
622        | MATRIX_CMD '(' expr ')'
623          {
624            if(iiExprArith1(&$$,&$3,MATRIX_CMD)) YYERROR;
625          }
626        | INTMAT_CMD '(' expr ')'
627          {
628            if(iiExprArith1(&$$,&$3,INTMAT_CMD)) YYERROR;
629          }
630        | CMD_M '(' exprlist ')'
631          {
632            if(iiExprArithM(&$$,&$3,$1)) YYERROR;
633          }
634        | quote_start expr quote_end
635          {
636            $$=$2;
637          }
638        | quote_start expr '=' expr quote_end
639          {
640            #ifdef SIQ
641            siq++;
642            if (siq>0)
643            { if (iiExprArith2(&$$,&$2,'=',&$4)) YYERROR; }
644            else
645            #endif
646            {
647              memset(&$$,0,sizeof($$));
648              $$.rtyp=NONE;
649              if (iiAssign(&$2,&$4)) YYERROR;
650            }
651            #ifdef SIQ
652            siq--;
653            #endif
654          }
655        | EVAL  '('
656          {
657            #ifdef SIQ
658            siq--;
659            #endif
660          }
661          expr ')'
662          {
663            #ifdef SIQ
664            if (siq<=0) $4.Eval();
665            #endif
666            $$=$4;
667            #ifdef SIQ
668            siq++;
669            #endif
670          }
671          ;
672
673quote_start:    QUOTE  '('
674          {
675            #ifdef SIQ
676            siq++;
677            #endif
678          }
679          ;
680
681quote_end: ')'
682          {
683            #ifdef SIQ
684            siq--;
685            #endif
686          }
687          ;
688
689expr_arithmetic:
690          expr  PLUSPLUS     %prec PLUSPLUS
691          {
692            if(iiExprArith1(&$$,&$1,PLUSPLUS)) YYERROR;
693          }
694        | expr  MINUSMINUS   %prec MINUSMINUS
695          {
696            if(iiExprArith1(&$$,&$1,MINUSMINUS)) YYERROR;
697          }
698        | expr  '+' expr
699          {
700            if(iiExprArith2(&$$,&$1,'+',&$3)) YYERROR;
701          }
702        | expr  '-' expr
703          {
704            if(iiExprArith2(&$$,&$1,'-',&$3)) YYERROR;
705          }
706        | expr  '*' expr
707          {
708            if(iiExprArith2(&$$,&$1,'*',&$3)) YYERROR;
709          }
710        | expr  '/' expr
711          {
712            if(iiExprArith2(&$$,&$1,'/',&$3)) YYERROR;
713          }
714        | expr  '^' expr
715          {
716            if(iiExprArith2(&$$,&$1,'^',&$3)) YYERROR;
717          }
718        | expr  '%' expr
719          {
720            if(iiExprArith2(&$$,&$1,'%',&$3)) YYERROR;
721          }
722        | expr  '>' expr
723          {
724            if(iiExprArith2(&$$,&$1,'>',&$3)) YYERROR;
725          }
726        | expr  '<' expr
727          {
728            if(iiExprArith2(&$$,&$1,'<',&$3)) YYERROR;
729          }
730        | expr  '&' expr
731          {
732            if(iiExprArith2(&$$,&$1,'&',&$3)) YYERROR;
733          }
734        | expr  '|' expr
735          {
736            if(iiExprArith2(&$$,&$1,'|',&$3)) YYERROR;
737          }
738        | expr  NOTEQUAL expr
739          {
740            if(iiExprArith2(&$$,&$1,NOTEQUAL,&$3)) YYERROR;
741          }
742        | expr  EQUAL_EQUAL expr
743          {
744            if(iiExprArith2(&$$,&$1,EQUAL_EQUAL,&$3)) YYERROR;
745          }
746        | expr  GE  expr
747          {
748            if(iiExprArith2(&$$,&$1,GE,&$3)) YYERROR;
749          }
750        | expr  LE expr
751          {
752            if(iiExprArith2(&$$,&$1,LE,&$3)) YYERROR;
753          }
754        | expr DOTDOT expr
755          {
756            if(iiExprArith2(&$$,&$1,DOTDOT,&$3)) YYERROR;
757          }
758        | NOT '(' expr ')'
759          {
760            memset(&$$,0,sizeof($$));
761            int i; TESTSETINT($3,i);
762            $$.rtyp  = INT_CMD;
763            $$.data = (void *)(i == 0 ? 1 : 0);
764          }
765        | '-' expr %prec UMINUS
766          {
767            if(iiExprArith1(&$$,&$2,'-')) YYERROR;
768          }
769        ;
770
771left_value:
772        declare_ip_variable cmdeq  { $$ = $1; }
773        | exprlist '='
774          {
775            if ($1.rtyp==0)
776            {
777              Werror("`%s` is undefined",$1.Name());
778              YYERROR;
779            }
780            $$ = $1;
781          }
782        ;
783
784
785extendedid:
786        UNKNOWN_IDENT
787        | '`' expr '`'
788          {
789            if ($2.Typ()!=STRING_CMD)
790            {
791              MYYERROR("string expression expected");
792            }
793            $$ = (char *)$2.CopyD();
794            $2.CleanUp();
795          }
796        ;
797
798currring_lists:
799        IDEAL_CMD | MODUL_CMD
800        /* put variables into the current ring */
801        ;
802
803declare_ip_variable:
804        ROOT_DECL elemexpr
805          {
806            if (iiDeclCommand(&$$,&$2,myynest,$1,&idroot)) YYERROR;
807          }
808        | ROOT_DECL_LIST elemexpr
809          {
810            if (iiDeclCommand(&$$,&$2,myynest,$1,&idroot)) YYERROR;
811          }
812        | RING_DECL elemexpr
813          {
814            #ifdef SIC
815            if ((sic) && (currRing==NULL))
816            {
817              if (iiDeclCommand(&$$,&$2,myynest,$1,NULL)) YYERROR;
818            }
819            else
820            #endif
821            {
822              if (iiDeclCommand(&$$,&$2,myynest,$1,&(currRing->idroot))) YYERROR;
823            }
824          }
825        | currring_lists elemexpr
826          {
827            #ifdef SIC
828            if ((sic) && (currRing==NULL))
829            {
830              if (iiDeclCommand(&$$,&$2,myynest,$1,NULL)) YYERROR;
831            }
832            else
833            #endif
834            {
835              if (iiDeclCommand(&$$,&$2,myynest,$1,&(currRing->idroot))) YYERROR;
836            }
837          }
838        | MATRIX_CMD elemexpr '[' expr ']' '[' expr ']'
839          {
840            if (iiDeclCommand(&$$,&$2,myynest,$1,&(currRing->idroot))) YYERROR;
841            #ifdef SIC
842            if (sic)
843            {
844            }
845            else
846            #endif
847            {
848              int r; TESTSETINT($4,r);
849              int c; TESTSETINT($7,c);
850              if (r < 1)
851                MYYERROR("rows must be greater than 0");
852              if (c < 0)
853                MYYERROR("cols must be greater than -1");
854              leftv v=&$$;
855              //while (v->next!=NULL) { v=v->next; }
856              idhdl h=(idhdl)v->data;
857              idDelete(&IDIDEAL(h));
858              IDMATRIX(h) = mpNew(r,c);
859              if (IDMATRIX(h)==NULL) YYERROR;
860            }
861          }
862        | MATRIX_CMD elemexpr
863          {
864            if (iiDeclCommand(&$$,&$2,myynest,$1,&(currRing->idroot))) YYERROR;
865          }
866        | INTMAT_CMD elemexpr '[' expr ']' '[' expr ']'
867          {
868            if (iiDeclCommand(&$$,&$2,myynest,$1,&idroot)) YYERROR;
869            #ifdef SIC
870            if (sic)
871            {
872            }
873            else
874            #endif
875            {
876              int r; TESTSETINT($4,r);
877              int c; TESTSETINT($7,c);
878              if (r < 1)
879                MYYERROR("rows must be greater than 0");
880              if (c < 0)
881                MYYERROR("cols must be greater than -1");
882              leftv v=&$$;
883              //while (v->next!=NULL) { v=v->next; }
884              idhdl h=(idhdl)v->data;
885              delete IDINTVEC(h);
886              IDINTVEC(h) = new intvec(r,c,0);
887              if (IDINTVEC(h)==NULL) YYERROR;
888            }
889          }
890        | INTMAT_CMD elemexpr
891          {
892            if (iiDeclCommand(&$$,&$2,myynest,$1,&idroot)) YYERROR;
893            leftv v=&$$;
894            idhdl h;
895            do
896            {
897               h=(idhdl)v->data;
898               delete IDINTVEC(h);
899               IDINTVEC(h) = new intvec(1,1,0);
900               v=v->next;
901            } while (v!=NULL);
902          }
903        | declare_ip_variable ',' elemexpr
904          {
905            int t=$1.Typ();
906            sleftv r;
907            memset(&r,0,sizeof(sleftv));
908            if ((BEGIN_RING<t) && (t<END_RING))
909            {
910              if (iiDeclCommand(&r,&$3,myynest,t,&(currRing->idroot))) YYERROR;
911            }
912            else
913            {
914              if (iiDeclCommand(&r,&$3,myynest,t,&idroot)) YYERROR;
915            }
916            leftv v=&$1;
917            while (v->next!=NULL) v=v->next;
918            v->next=(leftv)Alloc(sizeof(sleftv));
919            memcpy(v->next,&r,sizeof(sleftv));
920            $$=$1;
921          }
922        ;
923
924stringexpr:
925        STRINGTOK
926        | LIB_CMD
927          {
928            idhdl h = ggetid( "LIB" );
929            if (h==NULL) YYERROR;
930            $$ = mstrdup(IDSTRING(h));
931          }
932        ;
933
934rlist:
935        expr
936        | '(' expr ',' exprlist ')'
937          {
938            leftv v = &$2;
939            while (v->next!=NULL)
940            {
941              v=v->next;
942            }
943            v->next = (leftv)Alloc(sizeof(sleftv));
944            memcpy(v->next,&($4),sizeof(sleftv));
945            $$ = $2;
946          }
947        ;
948
949ordername:
950        UNKNOWN_IDENT
951        {
952          if (!($$=rOrderName($1)))
953            YYERROR;
954        }
955        ;
956
957orderelem:
958        ordername
959          {
960            memset(&$$,0,sizeof($$));
961            intvec *iv = new intvec(2);
962            (*iv)[0] = 1;
963            (*iv)[1] = $1;
964            $$.rtyp = INTVEC_CMD;
965            $$.data = (void *)iv;
966          }
967        | ordername '(' exprlist ')'
968          {
969            memset(&$$,0,sizeof($$));
970            leftv sl = &$3;
971            int slLength;
972            {
973              slLength =  exprlist_length(sl);
974              int l = 2 +  slLength;
975              intvec *iv = new intvec(l);
976              (*iv)[0] = slLength;
977              (*iv)[1] = $1;
978
979              int i = 2;
980              while ((i<l) && (sl!=NULL))
981              {
982                if (sl->Typ() == INT_CMD)
983                {
984                  (*iv)[i++] = (int)(sl->Data());
985                }
986                else if ((sl->Typ() == INTVEC_CMD)
987                ||(sl->Typ() == INTMAT_CMD))
988                {
989                  intvec *ivv = (intvec *)(sl->Data());
990                  int ll = 0,l = ivv->length();
991                  for (; l>0; l--)
992                  {
993                    (*iv)[i++] = (*ivv)[ll++];
994                  }
995                }
996                else
997                {
998                  delete iv;
999                  $3.CleanUp();
1000                  MYYERROR("wrong type in ordering");
1001                }
1002                sl = sl->next;
1003              }
1004              $$.rtyp = INTVEC_CMD;
1005              $$.data = (void *)iv;
1006            }
1007            $3.CleanUp();
1008          }
1009        ;
1010
1011OrderingList:
1012        orderelem
1013        |  orderelem ',' OrderingList
1014          {
1015            $$ = $1;
1016            $$.next = (sleftv *)Alloc(sizeof(sleftv));
1017            memcpy($$.next,&$3,sizeof(sleftv));
1018          }
1019        ;
1020
1021ordering:
1022        orderelem
1023        | '(' OrderingList ')'
1024          {
1025            $$ = $2;
1026          }
1027        ;
1028
1029cmdeq:  '='
1030          {
1031            expected_parms = TRUE;
1032          }
1033        ;
1034
1035
1036/* --------------------------------------------------------------------*/
1037/* section of pure commands                                            */
1038/* --------------------------------------------------------------------*/
1039
1040executecmd:
1041        EXECUTE_CMD expr
1042          {
1043            #ifdef SIC
1044            if (sic) MYYERROR("execute not supported");
1045            #endif
1046            if ($2.Typ() == STRING_CMD)
1047            {
1048              char * s = (char *)AllocL(strlen((char *)$2.Data()) + 4);
1049              strcpy( s, (char *)$2.Data());
1050              strcat( s, "\n;\n");
1051              $2.CleanUp();
1052              newBuffer(s,BT_execute);
1053            }
1054            else
1055            {
1056              MYYERROR("string expected");
1057            }
1058          }
1059        ;
1060
1061filecmd:
1062        '<' stringexpr ';'
1063          { if (iiPStart(NULL,$2,NULL)) YYERROR; }
1064        ;
1065
1066helpcmd:
1067        HELP_CMD STRINGTOK
1068          {
1069            singular_help($2,FALSE);
1070            FreeL((ADDRESS)$2);
1071          }
1072        | HELP_CMD
1073          {
1074            char *s=(char *)Alloc(10);
1075            strcpy(s,"index");
1076            singular_help(s,FALSE);
1077            Free((ADDRESS)s,10);
1078          }
1079        | EXAMPLE_CMD STRINGTOK
1080          {
1081            singular_help($2,TRUE);
1082            FreeL((ADDRESS)$2);
1083            if (inerror) YYERROR;
1084          }
1085        ;
1086
1087exportcmd:
1088        EXPORT_CMD exprlist
1089        {
1090          if (iiExport(&$2,0)) YYERROR;
1091        }
1092        | EXPORT_CMD exprlist extendedid expr
1093        {
1094          if ((strcmp($3,"to")!=0) ||
1095          (($4.Typ()!=PACKAGE_CMD) && ($4.Typ()!=INT_CMD)))
1096            MYYERROR("export <id> to <package|int>");
1097          FreeL((ADDRESS)$3);
1098          if ($4.Typ()==INT_CMD)
1099          {
1100            if (iiExport(&$2,((int)$4.Data())-1)) YYERROR;
1101          }
1102          else
1103          {
1104            if (iiExport(&$2,0,IDPACKAGE((idhdl)$4.data)->idroot))
1105              YYERROR;
1106          }
1107        }
1108        ;
1109
1110killcmd:
1111        KILL_CMD kill_any_identifier {;}
1112        ;
1113
1114kill_any_identifier:
1115        elemexpr
1116          {
1117            leftv v=&$1;
1118            do
1119            {
1120              if (v->rtyp!=IDHDL)
1121              {
1122                if (v->name!=NULL) Werror("`%s` is undefined in kill",v->name);
1123                else               WerrorS("kill what ?");
1124              }
1125              else
1126              {
1127                killhdl((idhdl)v->data);
1128              }
1129              v=v->next;
1130            } while (v!=NULL);
1131            $1.CleanUp();
1132          }
1133        | kill_any_identifier ',' elemexpr
1134          {
1135            if ($3.rtyp!=IDHDL)
1136            {
1137              if ($3.name!=NULL) Werror("`%s` is undefined",$3.name);
1138              else               WerrorS("kill what ?");
1139            }
1140            else
1141            {
1142              killhdl((idhdl)$3.data);
1143            }
1144            $3.CleanUp();
1145          }
1146        ;
1147
1148listcmd:
1149        LISTVAR_CMD '(' ROOT_DECL ')'
1150          {
1151            list_cmd($3,NULL,"// ",TRUE);
1152          }
1153        | LISTVAR_CMD '(' ROOT_DECL_LIST ')'
1154          {
1155            list_cmd($3,NULL,"// ",TRUE);
1156          }
1157        | LISTVAR_CMD '(' RING_DECL ')'
1158          {
1159            if ($3==QRING_CMD) $3=RING_CMD;
1160            list_cmd($3,NULL,"// ",TRUE);
1161          }
1162        | LISTVAR_CMD '(' currring_lists ')'
1163          {
1164            list_cmd($3,NULL,"// ",TRUE);
1165          }
1166        | LISTVAR_CMD '(' RING_CMD ')'
1167          {
1168            #ifdef SIC
1169            if (sic) MYYERROR("not implemented yet");
1170            #endif
1171            list_cmd(RING_CMD,NULL,"// ",TRUE);
1172          }
1173        | LISTVAR_CMD '(' MATRIX_CMD ')'
1174          {
1175            #ifdef SIC
1176            if (sic) MYYERROR("not implemented yet");
1177            #endif
1178            list_cmd(MATRIX_CMD,NULL,"// ",TRUE);
1179           }
1180        | LISTVAR_CMD '(' INTMAT_CMD ')'
1181          {
1182            #ifdef SIC
1183            if (sic) MYYERROR("not implemented yet");
1184            #endif
1185            list_cmd(INTMAT_CMD,NULL,"// ",TRUE);
1186          }
1187        | LISTVAR_CMD '(' PROC_CMD ')'
1188          {
1189            #ifdef SIC
1190            if (sic) MYYERROR("not implemented yet");
1191            #endif
1192            list_cmd(PROC_CMD,NULL,"// ",TRUE);
1193          }
1194        | LISTVAR_CMD '(' elemexpr ')'
1195          {
1196            #ifdef SIC
1197            if (sic) MYYERROR("not implemented yet");
1198            #endif
1199            list_cmd(0,$3.Name(),"// ",TRUE);
1200            $3.CleanUp();
1201          }
1202        | LISTVAR_CMD '(' ')'
1203          {
1204            #ifdef SIC
1205            if (sic) MYYERROR("not implemented yet");
1206            #endif
1207            list_cmd(-1,NULL,"// ",TRUE);
1208          }
1209        ;
1210
1211ringcmd1:
1212       RING_CMD { noringvars = TRUE; }
1213       ;
1214
1215ringcmd:
1216        ringcmd1
1217          elemexpr cmdeq
1218          rlist     ','      /* description of coeffs */
1219          rlist     ','      /* var names */
1220          ordering           /* list of (multiplier ordering (weight(s))) */
1221          {
1222            #ifdef SIC
1223            if (sic)
1224            {
1225            }
1226            #endif
1227            //noringvars = FALSE;
1228            if(!rInit($2.name,        /* ringname */
1229                     &$4,            /* characteristik and list of parameters*/
1230                     &$6,            /* names of ringvariables */
1231                     &$8,            /* ordering */
1232                     FALSE))         /* is not a dring */
1233            {
1234              MYYERROR("cannot make ring");
1235            }
1236            $4.CleanUp();
1237            $6.CleanUp();
1238            $8.CleanUp();
1239          }
1240        | ringcmd1 elemexpr
1241          {
1242            //noringvars = FALSE;
1243            if (!inerror) rDefault($2.name);
1244          }
1245        | DRING_CMD { noringvars = TRUE; }
1246          elemexpr cmdeq
1247          rlist     ','       /* description of coeffs */
1248          rlist     ','       /* var names */
1249          ordering           /* list of (multiplier ordering (weight(s))) */
1250          {
1251            #ifdef DRING
1252            idhdl h;
1253            //noringvars = FALSE;
1254            if(!(h=rInit($3.name,    /* ringname */
1255                     &$5,            /* characteristik and list of parameters*/
1256                     &$7,            /* names of ringvariables */
1257                     &$9,            /* ordering */
1258                     TRUE)))         /* is a dring */
1259            {
1260              YYERROR;
1261            }
1262            setFlag(h,FLAG_DRING);
1263            rDSet();
1264            $5.CleanUp();
1265            $7.CleanUp();
1266            $9.CleanUp();
1267            #endif
1268          }
1269        ;
1270
1271scriptcmd:
1272         LIB_CMD stringexpr
1273          {
1274            if (iiLibCmd($2)) YYERROR;
1275          }
1276        ;
1277
1278setrings:  SETRING_CMD | KEEPRING_CMD ;
1279
1280setringcmd:
1281        setrings expr
1282          {
1283            if (($1==KEEPRING_CMD) && (myynest==0))
1284               MYYERROR("only inside a proc allowed");
1285            const char * n=$2.Name();
1286            if ((($2.Typ()==RING_CMD)||($2.Typ()==QRING_CMD))
1287            && ($2.rtyp==IDHDL))
1288            {
1289              idhdl h=(idhdl)$2.data;
1290              if ($2.e!=NULL) h=rFindHdl((ring)$2.Data(),NULL);
1291              if ($1==KEEPRING_CMD)
1292              {
1293                if (h!=NULL)
1294                {
1295                  if (IDLEV(h)!=0)
1296                  {
1297                    if (iiExport(&$2,myynest-1)) YYERROR;
1298                    //if (TEST_OPT_KEEPVARS)
1299                    //{
1300                      idhdl p=IDRING(h)->idroot;
1301                      int prevlev=myynest-1;
1302                      while (p!=NULL)
1303                      {
1304                        if (IDLEV(p)==myynest) IDLEV(p)=prevlev;
1305                        p=IDNEXT(p);
1306                      }
1307                    //}
1308                  }
1309                  iiLocalRing[myynest-1]=IDRING(h);
1310                }
1311                else
1312                {
1313                  Werror("%s is no identifier",n);
1314                  $2.CleanUp();
1315                  YYERROR;
1316                }
1317              }
1318              if (h!=NULL) rSetHdl(h,TRUE);
1319              else
1320              {
1321                Werror("cannot find the name of the basering %s",n);
1322                $2.CleanUp();
1323                YYERROR;
1324              }
1325              $2.CleanUp();
1326            }
1327            else
1328            {
1329              Werror("%s is no name of a ring/qring",n);
1330              $2.CleanUp();
1331              YYERROR;
1332            }
1333          }
1334        ;
1335
1336typecmd:
1337        TYPE_CMD expr
1338          {
1339            if ($2.rtyp!=IDHDL) MYYERROR("identifier expected");
1340            #ifdef SIC
1341            if (sic)
1342            {
1343            }
1344            else
1345            #endif
1346            {
1347              idhdl h = (idhdl)$2.data;
1348              type_cmd(h);
1349            }
1350          }
1351        | exprlist
1352          {
1353            //Print("typ is %d, rtyp:%d\n",$1.Typ(),$1.rtyp);
1354            #ifdef SIQ
1355            if ($1.rtyp!=COMMAND)
1356            {
1357            #endif
1358              if ($1.Typ()==UNKNOWN)
1359              {
1360                if ($1.name!=NULL)
1361                {
1362                  Werror("`%s` is undefined",$1.name);
1363                  FreeL((ADDRESS)$1.name);
1364                }
1365                YYERROR;
1366              }
1367            #ifdef SIQ
1368            }
1369            #endif
1370            $1.Print(&sLastPrinted);
1371            $1.CleanUp();
1372          }
1373        ;
1374
1375/* --------------------------------------------------------------------*/
1376/* section of flow control                                             */
1377/* --------------------------------------------------------------------*/
1378
1379ifcmd: IF_CMD '(' expr ')' BLOCKTOK
1380          {
1381            #ifdef SIC
1382            if (sic)
1383            {
1384              //egPrint(IF_CMD,1,"if, 1\n");
1385              //egPrint(&$3);
1386              newBuffer( $5, BT_if);
1387            }
1388            else
1389            #endif
1390            {
1391              int i; TESTSETINT($3,i);
1392              if (i!=0)
1393              {
1394                newBuffer( $5, BT_if);
1395                //printf("if:new level %d\n",voice);
1396              }
1397              else
1398              {
1399                FreeL((ADDRESS)$5);
1400                ifswitch[voice]=1;
1401                //printf("if:(0):set ifsw=1 in voice %d\n",voice);
1402              }
1403            }
1404          }
1405        | ELSE_CMD BLOCKTOK
1406          {
1407            #ifdef SIC
1408            if (sic)
1409            {
1410            //egPrint(ELSE_CMD,0,"op: else, 0\n");
1411            newBuffer( $2, BT_else);
1412            }
1413            else
1414            #endif
1415            {
1416              if (ifswitch[voice]==1)
1417              {
1418                ifswitch[voice]=0;
1419                newBuffer( $2, BT_else);
1420              }
1421              else
1422              {
1423                if (ifswitch[voice]!=2)
1424                {
1425                  char *s=$2+strlen($2)-1;
1426                  while ((*s=='\0')||(*s=='\n')) s--;
1427                  s[1]='\0';
1428                  Warn("`else` without `if` in level %d",myynest);
1429                }
1430                FreeL((ADDRESS)$2);
1431              }
1432              ifswitch[voice]=0;
1433            }
1434          }
1435        | IF_CMD '(' expr ')' BREAK_CMD
1436          {
1437            #ifdef SIC
1438            if (sic)
1439            {
1440              //egPrint(IFBREAK,1,"ifbreak, 1\n");
1441              //egPrint(&$3);
1442            }
1443            else
1444            #endif
1445            {
1446              int i; TESTSETINT($3,i);
1447              if (i)
1448              {
1449                if (exitBuffer(BT_break)) YYERROR;
1450              }
1451              ifswitch[voice]=0;
1452            }
1453          }
1454        | BREAK_CMD
1455          {
1456            #ifdef SIC
1457            if (sic)
1458            {
1459            }
1460            else
1461            #endif
1462            {
1463              if (exitBuffer(BT_break)) YYERROR;
1464              ifswitch[voice]=0;
1465            }
1466          }
1467        | CONTINUE_CMD
1468          {
1469            #ifdef SIC
1470            if (sic)
1471            {
1472            }
1473            else
1474            #endif
1475            {
1476              contBuffer(BT_break);
1477              ifswitch[voice]=0;
1478            }
1479          }
1480      ;
1481
1482whilecmd:
1483        WHILE_CMD STRINGTOK BLOCKTOK
1484          {
1485            /* -> if(!$2) break; $3; continue;*/
1486            char * s = (char *)AllocL( strlen($2) + strlen($3) + 36);
1487            sprintf(s,"whileif (!(%s)) break;\n%scontinue;\n " ,$2,$3);
1488            newBuffer(s,BT_break);
1489            FreeL((ADDRESS)$2);
1490            FreeL((ADDRESS)$3);
1491          }
1492        ;
1493
1494forcmd:
1495        FOR_CMD STRINGTOK STRINGTOK STRINGTOK BLOCKTOK
1496          {
1497            /* $2 */
1498            /* if (!$3) break; $5; $4; continue; */
1499            char * s = (char *)AllocL( strlen($3)+strlen($4)+strlen($5)+36);
1500            sprintf(s,"forif (!(%s)) break;\n%s%s;\ncontinue;\n "
1501                   ,$3,$5,$4);
1502            FreeL((ADDRESS)$3);
1503            FreeL((ADDRESS)$4);
1504            FreeL((ADDRESS)$5);
1505            newBuffer(s,BT_break);
1506            s = (char *)AllocL( strlen($2) + 3);
1507            sprintf(s,"%s;\n",$2);
1508            FreeL((ADDRESS)$2);
1509            newBuffer(s,BT_if);
1510          }
1511        ;
1512
1513proccmd:
1514        PROC_CMD extendedid BLOCKTOK
1515          {
1516            #ifdef SIC
1517            if (sic)
1518            {
1519              FreeL((ADDRESS)$2);
1520              FreeL((ADDRESS)$3);
1521              MYYERROR("not implemented");
1522            }
1523            #endif
1524            idhdl h = enterid($2,myynest,PROC_CMD,&idroot,FALSE);
1525            if (h==NULL) {FreeL((ADDRESS)$3); YYERROR;}
1526            IDSTRING(h) = (char *)AllocL(strlen($3)+31);
1527            sprintf(IDSTRING(h),"parameter list #;\n%s;return();\n\n",$3);
1528            FreeL((ADDRESS)$3);
1529          }
1530        | PROC_CMD elemexpr '=' expr ';'
1531          {
1532            #ifdef SIC
1533            if (sic)
1534            {
1535              $4.CleanUp();
1536              FreeL((ADDRESS)$2);
1537              MYYERROR("not implemented");
1538            }
1539            #endif
1540            sleftv v;
1541            if ((iiDeclCommand(&v,&$2,myynest,PROC_CMD,&idroot,FALSE))
1542            || (iiAssign(&v,&($4)))) YYERROR;
1543          }
1544        | PROC_DEF STRINGTOK BLOCKTOK
1545          {
1546            idhdl h = enterid($1,myynest,PROC_CMD,&idroot,FALSE);
1547            if (h==NULL)
1548            {
1549              FreeL((ADDRESS)$2);
1550              FreeL((ADDRESS)$3);
1551              YYERROR;
1552            }
1553            char *args=iiProcArgs($2,FALSE);
1554            FreeL((ADDRESS)$2);
1555            IDSTRING(h) = (char *)AllocL(strlen($3)+strlen(args)+14);
1556            sprintf(IDSTRING(h),"%s\n%s;RETURN();\n\n",args,$3);
1557            FreeL((ADDRESS)args);
1558            FreeL((ADDRESS)$3);
1559            //Print(">>%s<<\n",IDSTRING(h));
1560          }
1561        ;
1562
1563parametercmd:
1564        PARAMETER declare_ip_variable
1565          {
1566            //Print("par:%s, %d\n",$2.Name(),$2.Typ());
1567            yylineno--;
1568            #ifdef SIC
1569            if (sic)
1570            {
1571              //egParameter(&$2);
1572            }
1573            else
1574            #endif
1575            {
1576              if (iiParameter(&$2)) YYERROR;
1577            }
1578          }
1579        | PARAMETER expr
1580          {
1581            //Print("par:%s, %d\n",$2.Name(),$2.Typ());
1582            sleftv tmp_expr;
1583            #ifdef SIC
1584            if (sic)
1585            {
1586              if (iiDeclCommand(&tmp_expr,&$2,myynest,DEF_CMD,&idroot))
1587                YYERROR;
1588              //egParameter(&$2);
1589            }
1590            else
1591            #endif
1592            {
1593              if ((iiDeclCommand(&tmp_expr,&$2,myynest,DEF_CMD,&idroot))
1594              || (iiParameter(&tmp_expr)))
1595                YYERROR;
1596            }
1597          }
1598        ;
1599
1600returncmd:
1601        RETURN '(' exprlist ')'
1602          {
1603            iiRETURNEXPR[myynest].Copy(&$3);
1604            $3.CleanUp();
1605            if (exitBuffer(BT_proc)) YYERROR;
1606          }
1607        | RETURN '(' ')'
1608          {
1609            iiRETURNEXPR[myynest].Init();
1610            iiRETURNEXPR[myynest].rtyp=NONE;
1611            if (exitBuffer(BT_proc)&&($1!=END_PROC)) YYERROR;
1612            if ($1==END_PROC) YYACCEPT;
1613          }
1614        ;
Note: See TracBrowser for help on using the repository browser.