source: git/m4/ax_python_with_version.m4 @ c2ff413

# AX_PYTHON_WITH_VERSION( [version], [path] )
# -----------------------------------------------------------------
# Handles the various --with-python commands.
# Input:
#   $1 is the minimun required python version
#   $2 is the optional search path for the python executable if needed
# Ouput:
#   PYTHON_USE (AM_CONDITIONAL) is true if python executable found
#   and --with-python was requested; otherwise false.
#   $PYTHON contains the full executable path to python if PYTHON_USE
#   is true.
#
# Example:
#   AX_PYTHON_WITH_VERSION([2.4])
#   or
#   AX_PYTHON_WITH_VERSION([2.4], "/usr/bin")

AC_DEFUN([AX_PYTHON_WITH_VERSION],
[
    AC_ARG_VAR([PYTHON],[Python Executable Path])

    # unless PYTHON was supplied to us (as a precious variable),
    # see if --with-python[=PythonExecutablePath], --with-python,
    # --without-python or --with-python=no was given.
    if test -z "$PYTHON"
    then
        AC_MSG_CHECKING(for --with-python)
        AC_ARG_WITH(
            python,
            AS_HELP_STRING([--with-python@<:@=@<:@embed,@:>@PYTHON@:>@],
                [absolute path name of Python executable]
            ),
            [],[withval="yes"]
        ) 
        py_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
        for elt in $withval; do
          IFS="$py_save_ifs"
          case $elt in
            embed|embedding)
              si_try_embed=true
            ;;
            static|dynamic|shared|module)
            ;;
            *)
            si_withval=$elt
          esac 
        done
        IFS="$py_save_ifs"
        if test x"$si_withval" = x""
        then
           withval="yes"
        else
           withval="$si_withval"
        fi

        AC_MSG_RESULT($withval)
        if test "$withval" = "no"
        then
            ax_python_use=false
        else        
            if test "$withval" = "yes"
            then
                # "yes" was specified, but we don't have a path
                # for the executable.
                # So, let's search the PATH Environment Variable.
                AC_PATH_PROG(
                    [PYTHON],
                    python,
                    [],
                    $2
                )
            else
                # $withval must be the executable path then.
                AC_SUBST([PYTHON], ["${withval}"])
            fi
            if test -z "$PYTHON"
            then
                AC_MSG_RESULT([no path to python found, skipping python interface!])
            else 
                AX_PYTHON_VERSION_CHECK([$1],
                                        [ ax_python_use=true
                                          si_embed_python=$si_try_embed
                                          AC_MSG_RESULT(yes)
                                          AX_PYTHON_PREFIX( )
                                          AX_PYTHON_LSPEC( )
                                          AX_PYTHON_CSPEC( )
                                        ],
                                        [ax_python_use=false
                                         AC_MSG_RESULT([too old, skipping python interface!])]
                )
            fi
        fi   

        if  test x"$si_embed_python" = x"true"
        then 
          AC_DEFINE(EMBED_PYTHON,1,integrate python)
          AC_SUBST(EMBED_PYOBJECT_CFLAGS,"\${PYTHON_CSPEC}")
          AC_SUBST(EMBED_PYOBJECT_LDFLAGS,"\${PYTHON_LSPEC}")
        fi
        if test x"$ax_python_use" = x"true" 
        then 
          AC_DEFINE(HAVE_PYTHON,1,[compile python-related stuff])
        fi
    fi
    
    AM_CONDITIONAL(PYTHON_USE, test x"$ax_python_use" = x"true")
    AM_CONDITIONAL(SI_EMBED_PYTHON, test x"$si_embed_python" = x"true")
    AM_CONDITIONAL(PYTHON_MODULE, test x"$si_embed_python" != x"true")

])