Context Navigation

configure.ac @ 09ed77

spielwiese

Last change on this file since 09ed77 was 09ed77, checked in by Hans Schoenemann <hannes@…>, 13 years ago
start to removed unneeded options from omalloc
Property mode set to `100644`
File size: 16.5 KB

Line
1	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
2	dnl File: configure.in
3	dnl Purpose: Process this file with autoconf to produce configure
4	dnl Author: obachman@mathematik.uni-kl.de (Olaf Bachmann)
5	dnl Created: 11/99
6	dnl Version: $Id$
7	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
8
9	AC_INIT(omalloc,0.9.6)
10	AC_CONFIG_SRCDIR(om_Alloc.c)
11
12	AC_CONFIG_AUX_DIR([.])
13
14	AM_MAINTAINER_MODE
15	AM_INIT_AUTOMAKE
16
17	AC_SUBST(VERSION)
18
19	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
20	dnl help for configure
21	dnl
22	AC_ARG_WITH(
23	external-config_h,
24	[ --with-external-config_h=HEADER_FILE
25	use HEADER_FILE for external configuration])
26	AC_ARG_WITH(
27	external-config_c,
28	[ --with-external-config_c=C_FILE
29	use C_FILE for external implementations])
30	AC_ARG_WITH(
31	malloc,
32	[ --with-malloc=system\|external
33	which malloc to use, default: malloc ])
34	AC_ARG_WITH(
35	external-malloc_h,
36	[ --with-external-malloc-h=HEADER_FILE
37	use HEADER_FILE for external malloc declaration])
38	AC_ARG_WITH(
39	external-malloc_c,
40	[ --with-external-malloc-c=C_FILE
41	use C_FILE for external malloc implementation])
42	AC_ARG_WITH(
43	valloc,
44	[ --with-valloc=mmap\|system\|emulate
45	how to get page-aligned memory, default: use first possible])
46	AC_ARG_WITH(
47	align,
48	[ --with-align=8\|sloppy\|strict
49	how memory is aligned,
50	default: if possible sloppy, else strict])
51	AC_ARG_WITH(
52	dense-bins,
53	[ --with-dense-bins use dense bin distribution])
54	AC_ARG_WITH(
55	inline,
56	[ --without-inline do not inline])
57	AC_ARG_WITH(
58	debug,
59	[ --without-debug disable all debugging facilities])
60	AC_ARG_WITH(
61	track,
62	[ --without-track disable debug tracking functionality])
63	AC_ARG_WITH(
64	track-fl,
65	[ --with-track-fl track file and line numbers])
66	AC_ARG_WITH(
67	track-return,
68	[ --with-track-return track return addresses])
69	AC_ARG_WITH(
70	track-backtrace,
71	[ --with-track-backtrace track stack backtraces])
72	AC_ARG_WITH(
73	track-custom,
74	[ --with-track-custom track custom values])
75	AC_ARG_WITH(
76	internal_debug,
77	[ --with-internal-debug
78	turn on internal debugging])
79	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
80	dnl compiler/make config
81	dnl
82	dnl I'm not sure why I did this
83	dnl if test "${CFLAGS+set}" != set; then
84	dnl CFLAGS="-O"
85	dnl ac_cflags_set=no
86	dnl fi
87
88	CPPFLAGS="-I.. -I."
89	AC_PROG_MAKE_SET
90	AC_PROG_CC
91	AC_PROG_CPP
92	AC_PROG_RANLIB
93	AC_PROG_LN_S
94	AC_PROG_INSTALL
95	AM_PROG_CC_C_O
96	AC_C_CONST
97	AC_C_INLINE
98
99	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
100	dnl check for programs
101	dnl
102	AC_CHECK_PROG(AR, ar, ar, :)
103	if test "$ac_cv_prog_AR" != ar; then
104	AC_MSG_ERROR(*** ar program not found)
105	fi
106	AC_CHECK_PROGS(PERL, perl, "no")
107	if test "$ac_cv_prog_PERL" = no; then
108	AC_MSG_ERROR(*** perl program not found)
109	fi
110
111	AC_CHECK_PROG(ADDR2LINE, addr2line, addr2line, no)
112	if test "$ac_cv_prog_ADDR2LINE" = addr2line; then
113	AC_DEFINE_UNQUOTED(OM_PROG_ADDR2LINE, "$ac_cv_prog_ADDR2LINE", "Name of addr2line")
114	fi
115
116	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
117	dnl header file checks
118	dnl
119	AC_HEADER_STDC
120	AC_CHECK_HEADERS(limits.h,,
121	AC_MSG_ERROR(Can not compile without limits.h))
122	AC_CHECK_HEADERS(unistd.h sys/mman.h fcntl.h /usr/include/malloc.h)
123
124	AC_CHECK_FUNCS(popen readlink getcwd getwd mmap sbrk random)
125
126	dnl llllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
127	dnl Find out more about particularity of the system
128	dnl
129
130	# sizes
131	AC_CHECK_SIZEOF(long,4)
132	AC_CHECK_SIZEOF(void*,4)
133	AC_CHECK_SIZEOF(double, 8)
134	AC_CHECK_SIZEOF(size_t, 4)
135
136	if test "$ac_cv_sizeof_long" != "$ac_cv_sizeof_voidp"; then
137	AC_MSG_ERROR(need equal sizes for long and void*)
138	fi
139	if test "$ac_cv_sizeof_voidp" != 4 && test "$ac_cv_sizeof_voidp" != 8; then
140	AC_MSG_ERROR(need void* to be 4 or 8 bytes long)
141	fi
142	if test "$ac_cv_sizeof_double" != 4 && test "$ac_cv_sizeof_double" != 8; then
143	AC_MSG_ERROR(need double to be 4 or 8 bytes long)
144	fi
145
146	dnl Set compiler, linker flags so that we can work with omalloc
147	BACKUP_CFLAGS=$CFLAGS
148	BACKUP_CXXFLAGS=$CXXFLAGS
149	BACKUP_LDFLAGS=$LDFLAGS
150	CFLAGS="$CFLAGS -I$srcdir"
151	CXXFLAGS="$CXXFLAGS -I$srcdir"
152
153	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
154	dnl figure out page size of the system
155	dnl
156	AC_MSG_CHECKING(size of system page)
157	AC_CACHE_VAL(ac_cv_pagesize,
158	AC_TRY_RUN([#include <stdio.h>
159	#include "omGetPageSize.h"
160
161	main()
162	{
163	FILE *f=fopen("conftestval", "w");
164	if (!f) exit(1);
165	fprintf(f, "%d\n", omalloc_getpagesize);
166	exit(0);
167	}], ac_cv_pagesize=`cat conftestval`, ac_cv_pagesize=0, ac_cv_pagesize=0))
168	# can not really handle pagesizes which are greater -- there must be a
169	# bug somewhere
170	if test $ac_cv_pagesize -gt 8192; then
171	ac_cv_pagesize=8192
172	fi
173	AC_MSG_RESULT($ac_cv_pagesize)
174	if test "$ac_cv_pagesize" = 4096 \|\| test "$ac_cv_pagesize" = 8192; then
175	AC_DEFINE_UNQUOTED(SIZEOF_SYSTEM_PAGE, $ac_cv_pagesize, "Page-size of the build-system")
176	else
177	AC_MSG_ERROR([need sytem page to be of size 4096 or 8192, but is $ac_cv_pagesize])
178	fi
179
180	AC_DEFINE_UNQUOTED(SIZEOF_OM_PAGE,SIZEOF_SYSTEM_PAGE,Page-size of the build-system)
181
182	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
183	dnl check whether mmap actually works
184	dnl
185	if test "$ac_cv_func_mmap" = yes; then
186	AC_MSG_CHECKING(whether mmap works)
187	AC_CACHE_VAL(ac_cv_working_mmap,
188	AC_TRY_RUN([
189	#include "omMmap.c"
190	main()
191	{
192	void* addr = omVallocMmap(128*${ac_cv_pagesize});
193	if (addr == 0 \|\| ((unsigned long) addr % ${ac_cv_pagesize}))
194	exit(1);
195	exit(omVfreeMmap(addr, 128*${ac_cv_pagesize}));
196	}], ac_cv_working_mmap=yes, ac_cv_working_mmap=no, ac_cv_working_mmap=no))
197	AC_MSG_RESULT($ac_cv_working_mmap)
198	if test "$ac_cv_working_mmap" = yes; then
199	AC_DEFINE(HAVE_WORKING_MMAP,1,"Whether we have a working mmap")
200	fi
201	fi
202
203	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
204	dnl for strict alignment
205	dnl
206	AC_CACHE_CHECK(whether alignment needs to be strict, ac_cv_align_need_strict,
207	AC_TRY_RUN([
208	main()
209	{
210	void* ptr = (void*) malloc(12);
211	double* d_ptr;
212	if ((unsigned long) ptr % 8 == 0) ptr = ptr + 4;
213	d_ptr = (double*) ptr;
214	*d_ptr = (double) 1.1;
215	if (*d_ptr != (double) 1.1) exit(1);
216	else exit(0);
217	}
218	], ac_cv_align_need_strict=no, ac_cv_align_need_strict=yes, ac_cv_align_need_strict=yes))
219
220	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
221	dnl external config files
222	dnl
223	AC_MSG_CHECKING(for external config files)
224	if test "${with_external_config_h+set}" = set; then
225	AC_DEFINE(OM_HAVE_EXTERNAL_CONFIG_H,1,"Whether we have external config.h")
226	EXTERNAL_CONFIG_HEADER=${with_external_config_h}
227	rm -f omExternalConfig.h
228	cp ${with_external_config_h} omExternalConfig.h
229	fi
230	if test "${with_external_config_c+set}" = set; then
231	AC_DEFINE(OM_HAVE_EXTERNAL_CONFIG_C,1,"Wether we have an external config.c")
232	EXTERNAL_CONFIG_SOURCE=${with_external_config_c}
233	fi
234	AC_SUBST(EXTERNAL_CONFIG_HEADER)
235	AC_SUBST(EXTERNAL_CONFIG_SOURCE)
236	if test "${EXTERNAL_CONFIG_HEADER+set}" = set \|\| test "${EXTERNAL_CONFIG_SOURCE+set}" = set; then
237	AC_MSG_RESULT(${EXTERNAL_CONFIG_HEADER} ${EXTERNAL_CONFIG_SOURCE})
238	else
239	AC_MSG_RESULT(none)
240	fi
241
242	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
243	dnl for malloc
244	dnl
245	AC_MSG_CHECKING(which malloc to use)
246	if test "${with_malloc}" = system; then
247	OM_MALLOC_HEADER=omMallocSystem.h
248	AC_DEFINE(OMALLOC_USES_MALLOC,1,the system allocator is called malloc)
249	AC_DEFINE(OMALLOC_USES_SYSTEM_MALLOC,1,use system malloc as system allocator)
250	elif test "${with_malloc}" = external; then
251	if test "${with_external_malloc_h+set}" != set; then
252	AC_MSG_ERROR(need --with_external_malloc_h for external malloc)
253	fi
254	AC_DEFINE(OMALLOC_USES_EXTERNAL_MALLOC,1,use external malloc as system allocator)
255	OM_MALLOC_HEADER=$with_external_malloc_h
256	OM_MALLOC_SOURCE=$with_external_malloc_c
257	AC_DEFINE(OMALLOC_USES_MALLOC,1,the system allocator is called malloc)
258	else ## default
259	OM_MALLOC_HEADER=omMallocSystem.h
260	AC_DEFINE(OMALLOC_USES_MALLOC,1,the system allocator is called malloc)
261	AC_DEFINE(OMALLOC_USES_SYSTEM_MALLOC,1,use system malloc as system allocator)
262	fi
263	AC_MSG_RESULT($with_malloc)
264
265	AC_SUBST(OM_MALLOC_HEADER)
266	AC_SUBST(OM_MALLOC_SOURCE)
267	if test "${OM_MALLOC_SOURCE+set}" = set; then
268	AC_DEFINE(OM_HAVE_MALLOC_SOURCE,1,"Whether we have the source for malloc ()")
269	fi
270
271	AC_MSG_CHECKING(whether malloc provides SizeOfAddr)
272	if test "${ac_cv_malloc_sizeof_addr}" = no; then
273	AC_MSG_RESULT( (cached) no)
274	elif test "${ac_cv_malloc_sizeof_addr}" = "${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}"; then
275	AC_MSG_RESULT( (cached) yes)
276	else
277	AC_TRY_RUN([
278	#include "$OM_MALLOC_HEADER"
279	#ifdef OM_HAVE_MALLOC_SOURCE
280	#include "$OM_MALLOC_SOURCE"
281	#endif
282
283	main()
284	{
285	void* addr = OM_MALLOC_MALLOC(512);
286	if (OM_MALLOC_SIZEOF_ADDR(addr) < 512)
287	exit(1);
288	exit(0);
289	}
290	], ac_cv_malloc_sizeof_addr="${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}", ac_cv_malloc_sizeof_addr=no, ac_cv_malloc_sizeof_addr=no)
291	if test "${ac_cv_malloc_sizeof_addr}" = no; then
292	AC_MSG_RESULT(no)
293	else
294	AC_MSG_RESULT(yes)
295	fi
296	fi
297	if test "$ac_cv_malloc_sizeof_addr" != no; then
298	AC_DEFINE(OM_MALLOC_PROVIDES_SIZEOF_ADDR,1,"Whether malloc provides SIZEOF_ADDR")
299	fi
300
301	dnl Restore user-specified CFLAGS, CXXFLAGS, LIBS
302
303	CFLAGS=$BACKUP_CFLAGS
304	CXXFLAGS=$BACKUP_CXXFLAGS
305	LDFLAGS=$BACKUP_LDFLAGS
306
307	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
308	dnl check whether valloc is provided and that it works
309	dnl
310	AC_MSG_CHECKING(whether working valloc exists)
311	if test "${ac_cv_working_valloc}" = no; then
312	AC_MSG_RESULT( (cached) no)
313	elif test "${ac_cv_working_valloc}" = "${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}"; then
314	AC_MSG_RESULT( (cached) yes)
315	else
316	AC_TRY_RUN([
317	#include "$OM_MALLOC_HEADER"
318	#ifdef OM_HAVE_MALLOC_SOURCE
319	#include "$OM_MALLOC_SOURCE"
320	#endif
321
322	main()
323	{
324	void* addr = OM_MALLOC_VALLOC(128*${ac_cv_pagesize});
325	if (addr == 0 \|\| ((unsigned long) addr % ${ac_cv_pagesize}))
326	exit(1);
327	OM_MALLOC_VFREE(addr, 128*${ac_cv_pagesize});
328	exit(0);
329	}
330	], ac_cv_working_valloc="${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}", ac_cv_working_valloc=no, ac_cv_working_valloc=no)
331	if test "${ac_cv_working_valloc}" = no; then
332	AC_MSG_RESULT(no)
333	else
334	AC_MSG_RESULT(yes)
335	fi
336	fi
337
338	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
339	dnl for valloc
340	dnl
341	AC_MSG_CHECKING(which valloc to use)
342	if test "${with_valloc+set}" != set \|\| test "${with_valloc}" = mmap; then
343	if test "${ac_cv_working_mmap}" = yes; then
344	with_valloc=mmap
345	AC_DEFINE(OM_HAVE_VALLOC_MMAP,1,"Have valloc")
346	else
347	with_valloc=malloc
348	fi
349	fi
350	if test "${with_valloc}" = malloc; then
351	if test "${ac_cv_working_valloc}" != no; then
352	AC_DEFINE(OM_HAVE_VALLOC_MALLOC,1,"Have valloc")
353	else
354	with_valloc=emulate
355	fi
356	fi
357	AC_MSG_RESULT($with_valloc)
358
359	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
360	dnl alignment
361	dnl
362	AC_MSG_CHECKING(how to align)
363	if test "$with_align" = 8 \|\| test "$ac_cv_sizeof_long" = 8; then
364	ac_cv_align=8
365	AC_DEFINE(OM_ALIGN_8,1,"Align to 8 bytes")
366	else
367	if test "$ac_cv_align_need_strict" = "yes" \|\| test "$with_align" = "strict"; then
368	AC_DEFINE(OM_ALIGNMENT_NEEDS_WORK,1,"Whether alignment needs work")
369	ac_cv_align="strict"
370	else
371	ac_cv_align="sloppy"
372	fi
373	fi
374	AC_MSG_RESULT($ac_cv_align)
375
376	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
377	dnl dense bins
378	dnl
379	AC_MSG_CHECKING(whether to use dense bins)
380	if test "$with_dense_bins" = yes; then
381	AC_MSG_RESULT(yes)
382	AC_DEFINE(OM_HAVE_DENSE_BIN_DISTRIBUTION,1,"Whether we have dense bins")
383	else
384	AC_MSG_RESULT(no)
385	fi
386
387	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
388	dnl debug and inline
389	dnl
390	AC_MSG_CHECKING(whether to disable debugging)
391	if test "$with_debug" != no; then
392	AC_MSG_RESULT(no)
393	else
394	AC_MSG_RESULT(yes)
395	AC_DEFINE(OM_NDEBUG,1,"Disable debug")
396	with_track=no
397	fi
398
399	AC_MSG_CHECKING(whether to have tracking debug functionality)
400	if test "$with_track" != no; then
401	AC_MSG_RESULT(yes)
402	AC_DEFINE(OM_HAVE_TRACK,1,"Have track")
403	else
404	AC_MSG_RESULT(no)
405	fi
406
407	AC_MSG_CHECKING(whether to use internal debug)
408	if test "$with_internal_debug" = yes; then
409	AC_MSG_RESULT(yes)
410	AC_DEFINE(OM_INTERNAL_DEBUG,1,"Internal debug")
411	with_inline=no
412	else
413	AC_MSG_RESULT(no)
414	fi
415
416	AC_MSG_CHECKING(whether to inline)
417	if test "$ac_cv_c_inline" != no && test "$with_inline" != no; then
418	AC_DEFINE_UNQUOTED(OM_INLINE, static $ac_cv_c_inline, "inline-declaration")
419	AC_DEFINE_UNQUOTED(OM_INLINE_DECL, static $ac_cv_c_inline, "inline-declaration")
420	AC_DEFINE_UNQUOTED(OM_INLINE_IMPL, static $ac_cv_c_inline, "inline-declaration")
421	AC_DEFINE_UNQUOTED(OM_INLINE_LOCAL, static $ac_cv_c_inline, "inline-declaration")
422	AC_MSG_RESULT(yes)
423	else
424	AC_DEFINE_UNQUOTED(OM_INLINE_DECL, extern, "inline-declaration")
425	AC_DEFINE_UNQUOTED(OM_INLINE_IMPL,, "inline-declaration")
426	AC_DEFINE_UNQUOTED(OM_INLINE_LOCAL, static, "inline-declaration")
427	AC_MSG_RESULT(no)
428	fi
429
430	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
431	dnl backtrace business
432	dnl
433	AC_MSG_CHECKING(whether GET_RET_ADDR works)
434	AC_CACHE_VAL(ac_cv_get_return_addr_works,
435	AC_TRY_RUN([
436	#include "omReturn.h"
437	int test_return_addr()
438	{
439	char* f;
440	GET_RET_ADDR(f);
441	return (int) f;
442	}
443	int main()
444	{
445	exit(! test_return_addr());
446	}
447	], ac_cv_get_return_addr_works=yes,
448	ac_cv_get_return_addr_works=no,
449	ac_cv_get_return_addr_works=no))
450	AC_MSG_RESULT($ac_cv_get_return_addr_works)
451	if test "$ac_cv_get_return_addr_works" = yes; then
452	AC_DEFINE(OM_GET_RETURN_ADDR_WORKS,1, "Whether get return address works")
453	fi
454
455	AC_MSG_CHECKING(whether omGetBackTrace works)
456	AC_CACHE_VAL(ac_cv_get_backtrace_works,
457	AC_TRY_RUN([
458	#include "omGetBackTrace.c"
459	#include <stdio.h>
460	int test_backtrace()
461	{
462	void* bt;
463	int i = omGetBackTrace(&bt, 0, 10);
464	return i;
465	}
466	int main()
467	{
468	int i;
469	omInitGetBackTrace();
470	i = test_backtrace();
471	if (i == 1) exit(0);
472	else exit(i+1);
473	}
474	], ac_cv_get_backtrace_works=yes,
475	ac_cv_get_backtrace_works=no,
476	ac_cv_get_backtrace_works=no))
477	AC_MSG_RESULT($ac_cv_get_backtrace_works)
478	if test "$ac_cv_get_backtrace_works" = yes; then
479	AC_DEFINE(OM_GET_BACKTRACE_WORKS,1,"Whether omInitGetBackTrace () works")
480	fi
481
482	AC_MSG_CHECKING(whether addr2line works)
483	AC_CACHE_VAL(ac_cv_prog_addr2line_works,
484	AC_TRY_RUN([
485	#undef OM_GET_BACKTRACE_WORKS
486	#include "omReturn.h"
487	#include "omStructs.h"
488	#include "omGetBackTrace.h"
489	#include "omRet2Info.c"
490	#include "omFindExec.c"
491
492
493	int test_Ret_2_Info()
494	{
495	void* bt;
496	int i;
497	struct omRetInfo_s info;
498
499	GET_RET_ADDR(bt);
500	i = omBackTrace_2_RetInfo(&bt, &info, 1);
501	return i;
502	}
503
504	int main(int argc, char** argv)
505	{
506	int i;
507	omInitRet_2_Info(*argv);
508	i = test_Ret_2_Info();
509	if (i==1) exit(0);
510	else exit (i+10);
511	}
512	], ac_cv_prog_addr2line_works=yes,
513	ac_cv_prog_addr2line_works=no,
514	ac_cv_prog_addr2line_works=no))
515	AC_MSG_RESULT($ac_cv_prog_addr2line_works)
516
517	AC_MSG_CHECKING(whether to track return addresses)
518	if test "$with_track_return" = no \|\| test "$ac_cv_get_return_addr_works" = no \|\| test "$ac_cv_prog_addr2line_works" != yes; then
519	with_track_return=no
520	else
521	AC_DEFINE(OM_TRACK_RETURN,1,"Whether to track return")
522	with_track_return=yes
523	fi
524	AC_MSG_RESULT($with_track_return)
525
526	AC_MSG_CHECKING(whether to track files and line numbers)
527	if test "$with_track_fl" = no && test "$with_track_return" = no; then
528	with_track_fl=yes
529	fi
530	if test "${with_track_fl+set}" != set; then
531	if test "$with_track_return" = yes; then
532	with_track_fl=no
533	else
534	with_track_fl=yes
535	fi
536	fi
537	AC_MSG_RESULT($with_track_fl)
538	if test "$with_track_fl" = yes; then
539	AC_DEFINE(OM_TRACK_FILE_LINE,1,"Whether to track file-line")
540	fi
541
542	AC_MSG_CHECKING(whether to track stack backtraces)
543	if test "$with_track" != no && test "$ac_cv_get_backtrace_works" = yes && test "$with_track_backtrace" != no && test "$ac_cv_prog_addr2line_works" = yes; then
544	with_track_backtrace=yes
545	AC_DEFINE(OM_TRACK_BACKTRACE,1,"Whether to track backtrace")
546	else
547	with_track_backtrace=no
548	fi
549	AC_MSG_RESULT($with_track_backtrace)
550
551	AC_MSG_CHECKING(whether to track custom values)
552	if test "$with_track" != no && test "$with_track_custom" = yes; then
553	AC_DEFINE(OM_TRACK_CUSTOM,1,"Enable custom tracking")
554	else
555	with_track_custom=no
556	fi
557	AC_MSG_RESULT($with_track_custom)
558
559	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
560	dnl figure out the return type of sbrk
561	dnl
562
563	AC_MSG_CHECKING(return type of sbrk)
564	AC_TRY_LINK(
565	#define __USE_MISC
566	#include <unistd.h>
567	,
568	void *sbrk();
569	,
570	AC_DEFINE(Void_t,void,"Type of void"),
571	AC_DEFINE(Void_t,char,"Type of void"),
572	)
573	AC_MSG_RESULT(Void_t)
574
575
576
577	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
578	dnl wrap it up
579	dnl
580	AC_CONFIG_HEADER(config.h omConfig.h omlimits.h)
581
582	AC_OUTPUT(Makefile, \
583	if test "$CONFIG_HEADERS"; then echo timestamp > stamp-h; fi)
584
585

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format