Context Navigation

configure.ac @ 49d2b5

spielwiese

Last change on this file since 49d2b5 was 49d2b5, checked in by Oleksandr Motsak <motsak@…>, 10 years ago
Correct detection of backtrace in omalloc's configure
Property mode set to `100644`
File size: 17.3 KB

Line
1	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
2	dnl File: configure.ac
3	dnl Purpose: Process this file with autoconf to produce configure
4	dnl Author: obachman@mathematik.uni-kl.de (Olaf Bachmann)
5	dnl Created: 11/99
6	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
7
8	AC_INIT([omalloc],[0.9.6])
9
10	AC_CONFIG_MACRO_DIR([../m4])
11	AC_CONFIG_AUX_DIR([.])
12	AC_CONFIG_SRCDIR(om_Alloc.c)
13	AC_CONFIG_HEADER([_config.h])
14
15	SING_RESET_FLAGS()
16
17	AM_MAINTAINER_MODE([enable])
18	AM_INIT_AUTOMAKE([-Wall foreign subdir-objects]) # -Wno-extra-portability -Werror silent-rules
19	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
20	m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
21
22	AM_SANITY_CHECK
23
24	# Add pre'prefixed config
25	AX_PREFIX_CONFIG_H([omConfig.h],[],[_config.h])
26
27	# SING_CHECK_SET_ARGS()
28
29	AC_SUBST(VERSION)
30
31	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
32	dnl help for configure
33	dnl
34
35	AC_ARG_WITH(
36	external-config_h,
37	[ --with-external-config_h=HEADER_FILE
38	use HEADER_FILE for external configuration])
39	AC_ARG_WITH(
40	external-config_c,
41	[ --with-external-config_c=C_FILE
42	use C_FILE for external implementations])
43	AC_ARG_WITH(
44	malloc,
45	[ --with-malloc=system\|external
46	which malloc to use, default: malloc ])
47	AC_ARG_WITH(
48	external-malloc_h,
49	[ --with-external-malloc-h=HEADER_FILE
50	use HEADER_FILE for external malloc declaration])
51	AC_ARG_WITH(
52	external-malloc_c,
53	[ --with-external-malloc-c=C_FILE
54	use C_FILE for external malloc implementation])
55	AC_ARG_WITH(
56	valloc,
57	[ --with-valloc=mmap\|system\|emulate
58	how to get page-aligned memory, default: use first possible])
59	AC_ARG_WITH(
60	align,
61	[ --with-align=8\|sloppy\|strict
62	how memory is aligned,
63	default: if possible sloppy, else strict])
64	AC_ARG_WITH(
65	dense-bins,
66	[ --with-dense-bins use dense bin distribution])
67	AC_ARG_WITH(
68	inline,
69	[ --without-inline do not inline])
70	AC_ARG_WITH(
71	debug,
72	[ --without-debug disable all debugging facilities])
73	AC_ARG_WITH(
74	track,
75	[ --without-track disable debug tracking functionality])
76	AC_ARG_WITH(
77	track-fl,
78	[ --with-track-fl track file and line numbers])
79	AC_ARG_WITH(
80	track-return,
81	[ --with-track-return track return addresses])
82	AC_ARG_WITH(
83	track-backtrace,
84	[ --with-track-backtrace track stack backtraces])
85	AC_ARG_WITH(
86	track-custom,
87	[ --with-track-custom track custom values])
88	AC_ARG_WITH(
89	internal_debug,
90	[ --with-internal-debug
91	turn on internal debugging])
92	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
93	dnl compiler/make config
94	dnl
95	dnl I'm not sure why I did this
96	dnl if test "${CFLAGS+set}" != set; then
97	dnl CFLAGS="-O"
98	dnl ac_cflags_set=no
99	dnl fi
100
101	CPPFLAGS="-I.. -I."
102	AC_PROG_MAKE_SET
103	AC_PROG_CC
104	AC_PROG_CPP
105
106	AC_PROG_LN_S
107	AC_PROG_INSTALL
108	AM_PROG_CC_C_O
109	# AM_PROG_AR
110	AC_C_CONST
111	AC_C_INLINE
112
113	LT_INIT
114
115
116	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
117	dnl check for programs
118	dnl
119	AC_CHECK_PROG(AR, ar, ar, :)
120	if test "$ac_cv_prog_AR" != ar; then
121	AC_MSG_ERROR(*** ar program not found)
122	fi
123	AC_CHECK_PROGS(PERL, perl, "no")
124	if test "$ac_cv_prog_PERL" = no; then
125	AC_MSG_ERROR(*** perl program not found)
126	fi
127
128	AC_CHECK_PROG(ADDR2LINE, addr2line, addr2line, no)
129	if test "$ac_cv_prog_ADDR2LINE" = addr2line; then
130	AC_DEFINE_UNQUOTED(OM_PROG_ADDR2LINE, "$ac_cv_prog_ADDR2LINE", "Name of addr2line")
131	fi
132
133	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
134	dnl header file checks
135	dnl
136	AC_HEADER_STDC
137	AC_CHECK_HEADERS(limits.h,,
138	AC_MSG_ERROR(Can not compile without limits.h))
139
140	AC_CHECK_HEADERS(unistd.h sys/mman.h fcntl.h /usr/include/malloc.h)
141
142	AC_CHECK_FUNCS(popen mmap sbrk random)
143
144	dnl llllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
145	dnl Find out more about particularity of the system
146	dnl
147
148	# sizes
149	AC_CHECK_SIZEOF(long,4)
150	AC_CHECK_SIZEOF(void*,4)
151	AC_CHECK_SIZEOF(double, 8)
152	AC_CHECK_SIZEOF(size_t, 4)
153
154	if test "$ac_cv_sizeof_long" != "$ac_cv_sizeof_voidp"; then
155	AC_MSG_ERROR(need equal sizes for long and void*)
156	fi
157	if test "$ac_cv_sizeof_voidp" != 4 && test "$ac_cv_sizeof_voidp" != 8; then
158	AC_MSG_ERROR(need void* to be 4 or 8 bytes long)
159	fi
160	if test "$ac_cv_sizeof_double" != 4 && test "$ac_cv_sizeof_double" != 8; then
161	AC_MSG_ERROR(need double to be 4 or 8 bytes long)
162	fi
163
164	dnl Set compiler, linker flags so that we can work with omalloc
165	BACKUP_CFLAGS=$CFLAGS
166	BACKUP_CXXFLAGS=$CXXFLAGS
167	BACKUP_LDFLAGS=$LDFLAGS
168
169	CFLAGS="$CFLAGS -I$srcdir"
170	CXXFLAGS="$CXXFLAGS -I$srcdir"
171
172	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
173	dnl figure out page size of the system
174	dnl
175	AC_MSG_CHECKING(size of system page)
176	AC_CACHE_VAL(ac_cv_pagesize,
177	AC_TRY_RUN([#include <stdio.h>
178	#include <stdlib.h>
179	#include "omGetPageSize.h"
180
181	int main()
182	{
183	FILE *f=fopen("conftestval", "w");
184	if (!f) exit(1);
185	fprintf(f, "%d\n", omalloc_getpagesize);
186	exit(0);
187	}], ac_cv_pagesize=`cat conftestval`, ac_cv_pagesize=0, ac_cv_pagesize=0))
188	# can not really handle pagesizes which are greater -- there must be a
189	# bug somewhere
190	if test $ac_cv_pagesize -gt 8192; then
191	ac_cv_pagesize=8192
192	fi
193	AC_MSG_RESULT($ac_cv_pagesize)
194	if test "$ac_cv_pagesize" = 4096 \|\| test "$ac_cv_pagesize" = 8192; then
195	AC_DEFINE_UNQUOTED(SIZEOF_SYSTEM_PAGE, $ac_cv_pagesize, "Page-size of the build-system")
196	else
197	AC_MSG_ERROR([need sytem page to be of size 4096 or 8192, but is $ac_cv_pagesize])
198	fi
199
200	AC_DEFINE_UNQUOTED(SIZEOF_OM_PAGE,SIZEOF_SYSTEM_PAGE,Page-size of the build-system)
201
202	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
203	dnl check whether mmap actually works
204	dnl
205	if test "$ac_cv_func_mmap" = yes; then
206	AC_MSG_CHECKING(whether mmap works)
207	AC_CACHE_VAL(ac_cv_working_mmap,
208	AC_TRY_RUN([
209	#include <stdlib.h>
210	#include "omMmap.c"
211	int main()
212	{
213	void* addr = omVallocMmap(128*${ac_cv_pagesize});
214	if (addr == 0 \|\| ((unsigned long) addr % ${ac_cv_pagesize}))
215	exit(1);
216	exit(omVfreeMmap(addr, 128*${ac_cv_pagesize}));
217	}], ac_cv_working_mmap=yes, ac_cv_working_mmap=no, ac_cv_working_mmap=no))
218	AC_MSG_RESULT($ac_cv_working_mmap)
219	if test "$ac_cv_working_mmap" = yes; then
220	AC_DEFINE(HAVE_WORKING_MMAP,1,"Whether we have a working mmap")
221	fi
222	fi
223
224	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
225	dnl for strict alignment
226	dnl
227	AC_CACHE_CHECK(whether alignment needs to be strict, ac_cv_align_need_strict,
228	AC_TRY_RUN([
229	#include <stdlib.h>
230	int main()
231	{
232	void* ptr = (void*) malloc(12);
233	volatile double* d_ptr;
234	if ((unsigned long) ptr % 8 == 0) ptr = ptr + 4;
235	d_ptr = (double*) ptr;
236	*d_ptr = (double) 1.25;
237	if (*d_ptr != (double) 1.25) exit(1);
238	else exit(0);
239	}
240	], ac_cv_align_need_strict=no, ac_cv_align_need_strict=yes, ac_cv_align_need_strict=yes))
241
242	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
243	dnl external config files
244	dnl
245	AC_MSG_CHECKING(for external config files)
246	if test "${with_external_config_h+set}" = set; then
247	AC_DEFINE(OM_HAVE_EXTERNAL_CONFIG_H,1,"Whether we have external config.h")
248	EXTERNAL_CONFIG_HEADER=${with_external_config_h}
249	rm -f omExternalConfig.h
250	cp ${with_external_config_h} omExternalConfig.h
251	fi
252	if test "${with_external_config_c+set}" = set; then
253	AC_DEFINE(OM_HAVE_EXTERNAL_CONFIG_C,1,"Wether we have an external config.c")
254	EXTERNAL_CONFIG_SOURCE=${with_external_config_c}
255	fi
256	AC_SUBST(EXTERNAL_CONFIG_HEADER)
257	AC_SUBST(EXTERNAL_CONFIG_SOURCE)
258	if test "${EXTERNAL_CONFIG_HEADER+set}" = set \|\| test "${EXTERNAL_CONFIG_SOURCE+set}" = set; then
259	AC_MSG_RESULT(${EXTERNAL_CONFIG_HEADER} ${EXTERNAL_CONFIG_SOURCE})
260	else
261	AC_MSG_RESULT(none)
262	fi
263
264	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
265	dnl for malloc
266	dnl
267	AC_MSG_CHECKING(which malloc to use)
268	if test "${with_malloc}" = system; then
269	OM_MALLOC_HEADER=omMallocSystem.h
270	AC_DEFINE(OMALLOC_USES_MALLOC,1,the system allocator is called malloc)
271	AC_DEFINE(OMALLOC_USES_SYSTEM_MALLOC,1,use system malloc as system allocator)
272	elif test "${with_malloc}" = external; then
273	if test "${with_external_malloc_h+set}" != set; then
274	AC_MSG_ERROR(need --with_external_malloc_h for external malloc)
275	fi
276	AC_DEFINE(OMALLOC_USES_EXTERNAL_MALLOC,1,use external malloc as system allocator)
277	OM_MALLOC_HEADER=$with_external_malloc_h
278	OM_MALLOC_SOURCE=$with_external_malloc_c
279	AC_DEFINE(OMALLOC_USES_MALLOC,1,the system allocator is called malloc)
280	else ## default
281	OM_MALLOC_HEADER=omMallocSystem.h
282	AC_DEFINE(OMALLOC_USES_MALLOC,1,the system allocator is called malloc)
283	AC_DEFINE(OMALLOC_USES_SYSTEM_MALLOC,1,use system malloc as system allocator)
284	fi
285	AC_MSG_RESULT($with_malloc)
286
287	AC_SUBST(OM_MALLOC_HEADER)
288	AC_SUBST(OM_MALLOC_SOURCE)
289	if test "${OM_MALLOC_SOURCE+set}" = set; then
290	AC_DEFINE(OM_HAVE_MALLOC_SOURCE,1,"Whether we have the source for malloc ()")
291	fi
292
293	AC_MSG_CHECKING(whether malloc provides SizeOfAddr)
294	if test "${ac_cv_malloc_sizeof_addr}" = no; then
295	AC_MSG_RESULT( (cached) no)
296	elif test "${ac_cv_malloc_sizeof_addr}" = "${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}"; then
297	AC_MSG_RESULT( (cached) yes)
298	else
299	AC_TRY_RUN([
300	#include <stdlib.h>
301	#include "$OM_MALLOC_HEADER"
302	#ifdef OM_HAVE_MALLOC_SOURCE
303	#include "$OM_MALLOC_SOURCE"
304	#endif
305
306	int main()
307	{
308	void* addr = OM_MALLOC_MALLOC(512);
309	#ifdef OM_MALLOC_SIZEOF_ADDR
310	if (OM_MALLOC_SIZEOF_ADDR(addr) < 512)
311	exit(1);
312	exit(0);
313	#else
314	exit(1);
315	#endif
316	}
317	], ac_cv_malloc_sizeof_addr="${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}", ac_cv_malloc_sizeof_addr=no, ac_cv_malloc_sizeof_addr=no)
318	if test "${ac_cv_malloc_sizeof_addr}" = no; then
319	AC_MSG_RESULT(no)
320	else
321	AC_MSG_RESULT(yes)
322	fi
323	fi
324	if test "$ac_cv_malloc_sizeof_addr" != no; then
325	AC_DEFINE(OM_MALLOC_PROVIDES_SIZEOF_ADDR,1,"Whether malloc provides SIZEOF_ADDR")
326	fi
327
328	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
329	dnl check whether valloc is provided and that it works
330	dnl
331	AC_MSG_CHECKING(whether working valloc exists)
332	if test "${ac_cv_working_valloc}" = no; then
333	AC_MSG_RESULT( (cached) no)
334	elif test "${ac_cv_working_valloc}" = "${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}"; then
335	AC_MSG_RESULT( (cached) yes)
336	else
337	AC_TRY_RUN([
338	#include <stdlib.h>
339	#include "$OM_MALLOC_HEADER"
340	#ifdef OM_HAVE_MALLOC_SOURCE
341	#include "$OM_MALLOC_SOURCE"
342	#endif
343
344	int main()
345	{
346	void* addr = OM_MALLOC_VALLOC(128*${ac_cv_pagesize});
347	if (addr == 0 \|\| ((unsigned long) addr % ${ac_cv_pagesize}))
348	exit(1);
349	OM_MALLOC_VFREE(addr, 128*${ac_cv_pagesize});
350	exit(0);
351	}
352	], ac_cv_working_valloc="${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}", ac_cv_working_valloc=no, ac_cv_working_valloc=no)
353	if test "${ac_cv_working_valloc}" = no; then
354	AC_MSG_RESULT(no)
355	else
356	AC_MSG_RESULT(yes)
357	fi
358	fi
359
360	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
361	dnl for valloc
362	dnl
363	AC_MSG_CHECKING(which valloc to use)
364	if test "${with_valloc+set}" != set \|\| test "${with_valloc}" = mmap; then
365	if test "${ac_cv_working_mmap}" = yes; then
366	with_valloc=mmap
367	AC_DEFINE(OM_HAVE_VALLOC_MMAP,1,"Have valloc")
368	else
369	with_valloc=malloc
370	fi
371	fi
372	if test "${with_valloc}" = malloc; then
373	if test "${ac_cv_working_valloc}" != no; then
374	AC_DEFINE(OM_HAVE_VALLOC_MALLOC,1,"Have valloc")
375	else
376	with_valloc=emulate
377	fi
378	fi
379	AC_MSG_RESULT($with_valloc)
380
381	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
382	dnl alignment
383	dnl
384	AC_MSG_CHECKING(how to align)
385	if test "$with_align" = 8 \|\| test "$ac_cv_sizeof_long" = 8; then
386	ac_cv_align=8
387	AC_DEFINE(OM_ALIGN_8,1,"Align to 8 bytes")
388	else
389	if test "$ac_cv_align_need_strict" = "yes" \|\| test "$with_align" = "strict"; then
390	AC_DEFINE(OM_ALIGNMENT_NEEDS_WORK,1,"Whether alignment needs work")
391	ac_cv_align="strict"
392	else
393	ac_cv_align="sloppy"
394	fi
395	fi
396	AC_MSG_RESULT($ac_cv_align)
397
398	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
399	dnl dense bins
400	dnl
401	AC_MSG_CHECKING(whether to use dense bins)
402	if test "$with_dense_bins" = yes; then
403	AC_MSG_RESULT(yes)
404	AC_DEFINE(OM_HAVE_DENSE_BIN_DISTRIBUTION,1,"Whether we have dense bins")
405	else
406	AC_MSG_RESULT(no)
407	fi
408
409	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
410	dnl debug and inline
411	dnl
412	save_cflags="$CFLAGS"
413	AC_MSG_CHECKING(whether to disable debugging)
414	if test "$with_debug" != no; then
415	AC_MSG_RESULT(no)
416	CFLAGS="$CFLAGS -g"
417	else
418	AC_MSG_RESULT(yes)
419	AC_DEFINE(OM_NDEBUG,1,"Disable debug")
420	with_track=no
421	fi
422	AM_CONDITIONAL([WANT_DEBUG],[test x"$with_debug" = xyes])
423
424	AC_MSG_CHECKING(whether to have tracking debug functionality)
425	if test "$with_track" != no; then
426	AC_MSG_RESULT(yes)
427	AC_DEFINE(OM_HAVE_TRACK,1,"Have track")
428	else
429	AC_MSG_RESULT(no)
430	fi
431
432	AC_MSG_CHECKING(whether to use internal debug)
433	if test "$with_internal_debug" = yes; then
434	AC_MSG_RESULT(yes)
435	AC_DEFINE(OM_INTERNAL_DEBUG,1,"Internal debug")
436	with_inline=no
437	else
438	AC_MSG_RESULT(no)
439	fi
440
441	AC_MSG_CHECKING(whether to inline)
442	if test "$ac_cv_c_inline" != no && test "$with_inline" != no; then
443	AC_DEFINE_UNQUOTED(OM_INLINE, static $ac_cv_c_inline, "inline-declaration")
444	AC_DEFINE_UNQUOTED(OM_INLINE_DECL, static $ac_cv_c_inline, "inline-declaration")
445	AC_DEFINE_UNQUOTED(OM_INLINE_IMPL, static $ac_cv_c_inline, "inline-declaration")
446	AC_DEFINE_UNQUOTED(OM_INLINE_LOCAL, static $ac_cv_c_inline, "inline-declaration")
447	AC_MSG_RESULT(yes)
448	else
449	AC_DEFINE_UNQUOTED(OM_INLINE_DECL, extern, "inline-declaration")
450	AC_DEFINE_UNQUOTED(OM_INLINE_IMPL,, "inline-declaration")
451	AC_DEFINE_UNQUOTED(OM_INLINE_LOCAL, static, "inline-declaration")
452	AC_MSG_RESULT(no)
453	fi
454
455	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
456	dnl backtrace business
457	dnl
458	AC_MSG_CHECKING(whether GET_RET_ADDR works)
459	AC_CACHE_VAL(ac_cv_get_return_addr_works,
460	AC_TRY_RUN([
461	#include <stdlib.h>
462	#include "omReturn.h"
463	int test_return_addr()
464	{
465	char* f;
466	GET_RET_ADDR(f);
467	return (int)(long) f;
468	}
469	int main()
470	{
471	exit(! test_return_addr());
472	}
473	], ac_cv_get_return_addr_works=yes,
474	ac_cv_get_return_addr_works=no,
475	ac_cv_get_return_addr_works=no))
476	AC_MSG_RESULT($ac_cv_get_return_addr_works)
477	if test "$ac_cv_get_return_addr_works" = yes; then
478	AC_DEFINE(OM_GET_RETURN_ADDR_WORKS,1, "Whether get return address works")
479	fi
480
481	AC_MSG_CHECKING(whether omGetBackTrace works)
482	AC_CACHE_VAL(ac_cv_get_backtrace_works,
483	AC_TRY_RUN([
484	#include <stdio.h>
485	#include <stdlib.h>
486	#include "omGetBackTrace.c"
487	int test_backtrace0()
488	{
489	void* bt @<:@ 10 @:>@ ;
490	int i = omGetBackTrace(bt, 0, 10);
491	return i;
492	}
493	int test_backtrace(){ return test_backtrace0(); }
494	int main()
495	{
496	int i;
497	#ifdef __APPLE__
498	/* omGetBackTrace crashes on OsX for i>2 */
499	i=0;
500	#else
501	omInitGetBackTrace();
502	i = test_backtrace();
503	#endif
504	if (i > 0) exit(0);
505	else exit(i+10);
506	}
507	], ac_cv_get_backtrace_works=yes,
508	ac_cv_get_backtrace_works=no,
509	ac_cv_get_backtrace_works=no))
510	AC_MSG_RESULT($ac_cv_get_backtrace_works)
511	if test "$ac_cv_get_backtrace_works" = yes; then
512	AC_DEFINE(OM_GET_BACKTRACE_WORKS,1,"Whether omInitGetBackTrace () works")
513	fi
514
515	AC_MSG_CHECKING(whether addr2line works)
516	AC_CACHE_VAL(ac_cv_prog_addr2line_works,
517	AC_TRY_RUN([
518	#include <stdlib.h>
519	#include "omReturn.h"
520	#include "omStructs.h"
521	/* #include "omGetBackTrace.h" */
522	#include "omGetBackTrace.c"
523	#include "omRet2Info.c"
524
525	int test_Ret_2_Info()
526	{
527	void* bt;
528	int i;
529	struct omRetInfo_s info;
530
531	GET_RET_ADDR(bt);
532	i = omBackTrace_2_RetInfo(&bt, &info, 1);
533	return i;
534	}
535
536	int main(int argc, char** argv)
537	{
538	int i;
539	omInitRet_2_Info(*argv);
540	i = test_Ret_2_Info();
541	if (i==1) exit(0);
542	else exit (i+10);
543	}
544	], ac_cv_prog_addr2line_works=yes,
545	ac_cv_prog_addr2line_works=no,
546	ac_cv_prog_addr2line_works=no))
547	AC_MSG_RESULT($ac_cv_prog_addr2line_works)
548
549	CFLAGS="$save_cflags"
550
551	AC_MSG_CHECKING(whether to track return addresses)
552	if test "$with_track_return" = no \|\| test "$ac_cv_get_return_addr_works" = no \|\| test "$ac_cv_prog_addr2line_works" != yes; then
553	with_track_return=no
554	else
555	AC_DEFINE(OM_TRACK_RETURN,1,"Whether to track return")
556	with_track_return=yes
557	fi
558	AC_MSG_RESULT($with_track_return)
559
560	AC_MSG_CHECKING(whether to track files and line numbers)
561	if test "$with_track_fl" = no && test "$with_track_return" = no; then
562	with_track_fl=yes
563	fi
564	if test "${with_track_fl+set}" != set; then
565	if test "$with_track_return" = yes; then
566	with_track_fl=no
567	else
568	with_track_fl=yes
569	fi
570	fi
571	AC_MSG_RESULT($with_track_fl)
572	if test "$with_track_fl" = yes; then
573	AC_DEFINE(OM_TRACK_FILE_LINE,1,"Whether to track file-line")
574	fi
575
576	AC_MSG_CHECKING(whether to track stack backtraces)
577	if test "$with_track" != no && test "$ac_cv_get_backtrace_works" = yes && test "$with_track_backtrace" != no && test "$ac_cv_prog_addr2line_works" = yes; then
578	with_track_backtrace=yes
579	AC_DEFINE(OM_TRACK_BACKTRACE,1,"Whether to track backtrace")
580	else
581	with_track_backtrace=no
582	fi
583	AC_MSG_RESULT($with_track_backtrace)
584
585	AC_MSG_CHECKING(whether to track custom values)
586	if test "$with_track" != no && test "$with_track_custom" = yes; then
587	AC_DEFINE(OM_TRACK_CUSTOM,1,"Enable custom tracking")
588	else
589	with_track_custom=no
590	fi
591	AC_MSG_RESULT($with_track_custom)
592
593	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
594	dnl figure out the return type of sbrk
595	dnl
596
597	AC_MSG_CHECKING(return type of sbrk)
598	AC_TRY_LINK(
599	#define __USE_MISC
600	#include <unistd.h>
601	,
602	void *sbrk();
603	,
604	AC_DEFINE(Void_t,void,"Type of void"),
605	AC_DEFINE(Void_t,char,"Type of void"),
606	)
607	AC_MSG_RESULT(Void_t)
608
609
610	AC_DEFINE(OM_PROVIDE_MALLOC,0,[Provide NO standard routines!])
611
612
613	dnl Restore user-specified CFLAGS, CXXFLAGS, LIBS
614
615	CFLAGS=$BACKUP_CFLAGS
616	CXXFLAGS=$BACKUP_CXXFLAGS
617	LDFLAGS=$BACKUP_LDFLAGS
618
619	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
620	dnl wrap it up
621	dnl
622	AC_CONFIG_FILES([Makefile omalloc.pc])
623	AC_OUTPUT
624

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format