Context Navigation

configure.in @ fe6cc2

spielwiese

Last change on this file since fe6cc2 was fe6cc2, checked in by Hans Schönemann <hannes@…>, 22 years ago
*hannes: Void_t git-svn-id: file:///usr/local/Singular/svn/trunk@5430 2c84dea3-7e68-4137-9b89-c4e89433aadc
Property mode set to `100644`
File size: 16.3 KB

Line
1	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
2	dnl File: configure.in
3	dnl Purpose: Process this file with autoconf to produce configure
4	dnl Author: obachman@mathematik.uni-kl.de (Olaf Bachmann)
5	dnl Created: 11/99
6	dnl Version: $Id: configure.in,v 1.14 2001-05-15 12:19:38 Singular Exp $
7	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
8
9	AC_INIT(om_Alloc.c)
10
11	VERSION=0.9.5
12	AC_SUBST(VERSION)
13
14	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
15	dnl help for configure
16	dnl
17	AC_ARG_WITH(
18	external-config_h,
19	[ --with-external-config_h=HEADER_FILE
20	use HEADER_FILE for external configuration])
21	AC_ARG_WITH(
22	external-config_c,
23	[ --with-external-config_c=C_FILE
24	use C_FILE for external implementations])
25	AC_ARG_WITH(
26	malloc,
27	[ --with-malloc=system\|dlmalloc\|gmalloc\|pmalloc\|external
28	which malloc to use, default: dlmalloc ])
29	AC_ARG_WITH(
30	external-malloc_h,
31	[ --with-external-malloc-h=HEADER_FILE
32	use HEADER_FILE for external malloc declaration])
33	AC_ARG_WITH(
34	external-malloc_c,
35	[ --with-external-malloc-c=C_FILE
36	use C_FILE for external malloc implementation])
37	AC_ARG_WITH(
38	valloc,
39	[ --with-valloc=mmap\|malloc\|emulate
40	how to get page-aligned memory, default: use first possible])
41	AC_ARG_WITH(
42	provide-malloc,
43	[ --with-provide-malloc=yes\|debug\|malloc
44	provide normal\|debug\|underlying malloc ANSI-C conforming
45	versions of malloc\|calloc\|realloc\|free])
46	AC_ARG_WITH(
47	emulate-omalloc,
48	[ --with-emulate-omalloc
49	provide only omallocs interface, but do not use its features])
50	AC_ARG_WITH(
51	align,
52	[ --with-align=8\|sloppy\|strict
53	how memory is aligned,
54	default: if possible sloppy, else strict])
55	AC_ARG_WITH(
56	dense-bins,
57	[ --with-dense-bins use dense bin distribution])
58	AC_ARG_WITH(
59	inline,
60	[ --without-inline do not inline])
61	AC_ARG_WITH(
62	debug,
63	[ --without-debug disable all debugging facilities])
64	AC_ARG_WITH(
65	track,
66	[ --without-track disable debug tracking functionality])
67	AC_ARG_WITH(
68	track-fl,
69	[ --with-track-fl track file and line numbers])
70	AC_ARG_WITH(
71	track-return,
72	[ --with-track-return track return addresses])
73	AC_ARG_WITH(
74	track-backtrace,
75	[ --with-track-backtrace track stack backtraces])
76	AC_ARG_WITH(
77	track-custom,
78	[ --with-track-custom track custom values])
79	AC_ARG_WITH(
80	internal_debug,
81	[ --with-internal-debug
82	turn on internal debugging])
83	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
84	dnl compiler/make config
85	dnl
86	dnl I'm not sure why I did this
87	dnl if test "${CFLAGS+set}" != set; then
88	dnl CFLAGS="-O"
89	dnl ac_cflags_set=no
90	dnl fi
91
92	AC_PROG_MAKE_SET
93	AC_PROG_CC
94	AC_PROG_CPP
95	AC_PROG_RANLIB
96	AC_PROG_LN_S
97	AC_PROG_INSTALL
98	AC_C_CONST
99	AC_C_INLINE
100
101	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
102	dnl check for programs
103	dnl
104	AC_CHECK_PROG(AR, ar, ar, :)
105	if test "$ac_cv_prog_AR" != ar; then
106	AC_MSG_ERROR(*** ar program not found)
107	fi
108	AC_CHECK_PROGS(PERL, perl, "no")
109	if test "$ac_cv_prog_PERL" = no; then
110	AC_MSG_ERROR(*** perl program not found)
111	fi
112
113	AC_CHECK_PROG(ADDR2LINE, addr2line, addr2line, no)
114	if test "$ac_cv_prog_ADDR2LINE" = addr2line; then
115	AC_DEFINE_UNQUOTED(OM_PROG_ADDR2LINE, "$ac_cv_prog_ADDR2LINE")
116	fi
117
118	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
119	dnl header file checks
120	dnl
121	AC_HEADER_STDC
122	AC_CHECK_HEADERS(limits.h,,
123	AC_MSG_ERROR(Can not compile without limits.h))
124	AC_CHECK_HEADERS(unistd.h sys/mman.h fcntl.h /usr/include/malloc.h)
125
126	AC_CHECK_FUNCS(popen readlink getcwd getwd mmap sbrk random)
127
128	dnl llllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
129	dnl Find out more about particularity of the system
130	dnl
131
132	# sizes
133	AC_CHECK_SIZEOF(long,4)
134	AC_CHECK_SIZEOF(void*,4)
135	AC_CHECK_SIZEOF(double, 8)
136	AC_CHECK_SIZEOF(size_t, 4)
137
138	if test "$ac_cv_sizeof_long" != "$ac_cv_sizeof_voidp"; then
139	AC_MSG_ERROR(need equal sizes for long and void*)
140	fi
141	if test "$ac_cv_sizeof_voidp" != 4 && test "$ac_cv_sizeof_voidp" != 8; then
142	AC_MSG_ERROR(need void* to be 4 or 8 bytes long)
143	fi
144	if test "$ac_cv_sizeof_double" != 4 && test "$ac_cv_sizeof_double" != 8; then
145	AC_MSG_ERROR(need double to be 4 or 8 bytes long)
146	fi
147
148	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
149	dnl figure out page size of the system
150	dnl
151	AC_MSG_CHECKING(size of system page)
152	AC_CACHE_VAL(ac_cv_pagesize,
153	AC_TRY_RUN([#include <stdio.h>
154	#include "omGetPageSize.h"
155
156	main()
157	{
158	FILE *f=fopen("conftestval", "w");
159	if (!f) exit(1);
160	fprintf(f, "%d\n", omalloc_getpagesize);
161	exit(0);
162	}], ac_cv_pagesize=`cat conftestval`, ac_cv_pagesize=0, ac_cv_pagesize=0))
163	# can not really handle pagesizes which are greater -- there must be a
164	# bug somewhere
165	if test $ac_cv_pagesize -gt 8192; then
166	ac_cv_pagesize=8192
167	fi
168	AC_MSG_RESULT($ac_cv_pagesize)
169	if test "$ac_cv_pagesize" = 4096 \|\| test "$ac_cv_pagesize" = 8192; then
170	AC_DEFINE_UNQUOTED(SIZEOF_SYSTEM_PAGE, $ac_cv_pagesize)
171	else
172	AC_MSG_ERROR(need sytem page to be of size 4096 or 8192, but is $ac_cv_pagesize)
173	fi
174
175	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
176	dnl check whether mmap actually works
177	dnl
178	if test "$ac_cv_func_mmap" = yes; then
179	AC_MSG_CHECKING(whether mmap works)
180	AC_CACHE_VAL(ac_cv_working_mmap,
181	AC_TRY_RUN([
182	#include "omMmap.c"
183	main()
184	{
185	void* addr = omVallocMmap(128*${ac_cv_pagesize});
186	if (addr == 0 \|\| ((unsigned long) addr % ${ac_cv_pagesize}))
187	exit(1);
188	exit(omVfreeMmap(addr, 128*${ac_cv_pagesize}));
189	}], ac_cv_working_mmap=yes, ac_cv_working_mmap=no, ac_cv_working_mmap=no))
190	AC_MSG_RESULT($ac_cv_working_mmap)
191	if test "$ac_cv_working_mmap" = yes; then
192	AC_DEFINE(HAVE_WORKING_MMAP)
193	fi
194	fi
195
196	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
197	dnl for strict alignment
198	dnl
199	AC_CACHE_CHECK(whether alignment needs to be strict, ac_cv_align_need_strict,
200	AC_TRY_RUN([
201	main()
202	{
203	void* ptr = (void*) malloc(12);
204	double* d_ptr;
205	if ((unsigned long) ptr % 8 == 0) ptr = ptr + 4;
206	d_ptr = (double*) ptr;
207	*d_ptr = (double) 1.1;
208	if (*d_ptr != (double) 1.1) exit(1);
209	else exit(0);
210	}
211	], ac_cv_align_need_strict=no, ac_cv_align_need_strict=yes, ac_cv_align_need_strict=yes))
212
213	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
214	dnl external config files
215	dnl
216	AC_MSG_CHECKING(for external config files)
217	if test "${with_external_config_h+set}" = set; then
218	AC_DEFINE(OM_HAVE_EXTERNAL_CONFIG_H)
219	EXTERNAL_CONFIG_HEADER=${with_external_config_h}
220	rm -f omExternalConfig.h
221	cp ${with_external_config_h} omExternalConfig.h
222	fi
223	if test "${with_external_config_c+set}" = set; then
224	AC_DEFINE(OM_HAVE_EXTERNAL_CONFIG_C)
225	EXTERNAL_CONFIG_SOURCE=${with_external_config_c}
226	fi
227	AC_SUBST(EXTERNAL_CONFIG_HEADER)
228	AC_SUBST(EXTERNAL_CONFIG_SOURCE)
229	if test "${EXTERNAL_CONFIG_HEADER+set}" = set \|\| test "${EXTERNAL_CONFIG_SOURCE+set}" = set; then
230	AC_MSG_RESULT(${EXTERNAL_CONFIG_HEADER} ${EXTERNAL_CONFIG_SOURCE})
231	else
232	AC_MSG_RESULT(none)
233	fi
234
235	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
236	dnl for malloc
237	dnl
238	AC_MSG_CHECKING(which malloc to use)
239	if test "${with_malloc}" = system; then
240	OM_MALLOC_HEADER=omMallocSystem.h
241	AC_DEFINE(OMALLOC_USES_MALLOC)
242	if test "${with_provide_malloc}" = yes \|\| test "${with_provide_malloc}" = debug; then
243	AC_MSG_ERROR("can not provide malloc for --with-malloc=system")
244	fi
245	elif test "${with_malloc}" = gmalloc; then
246	OM_MALLOC_HEADER=gmalloc.h
247	OM_MALLOC_SOURCE=gmalloc.c
248	elif test "${with_malloc}" = pmalloc; then
249	OM_MALLOC_HEADER=pmalloc.h
250	OM_MALLOC_SOURCE=pmalloc.c
251	elif test "${with_malloc}" = external; then
252	if test "${with_external_malloc_h+set}" != set; then
253	AC_MSG_ERROR(need --with_external_malloc_h for external malloc)
254	fi
255	if test "${with_provide_malloc}" = yes \|\| test "${with_provide_malloc}" = debug; then
256	AC_MSG_ERROR("can not provide malloc for --with_malloc=external")
257	fi
258	OM_MALLOC_HEADER=$with_external_malloc_h
259	OM_MALLOC_SOURCE=$with_external_malloc_c
260	AC_DEFINE(OMALLOC_USES_MALLOC)
261	else
262	with_malloc=dlmalloc
263	OM_MALLOC_HEADER=dlmalloc.h
264	OM_MALLOC_SOURCE=dlmalloc.c
265	fi
266	AC_MSG_RESULT($with_malloc)
267
268	AC_SUBST(OM_MALLOC_HEADER)
269	AC_SUBST(OM_MALLOC_SOURCE)
270	if test "${OM_MALLOC_SOURCE+set}" = set; then
271	AC_DEFINE(OM_HAVE_MALLOC_SOURCE)
272	fi
273
274	AC_MSG_CHECKING(whether malloc provides SizeOfAddr)
275	if test "${ac_cv_malloc_sizeof_addr}" = no; then
276	AC_MSG_RESULT( (cached) no)
277	elif test "${ac_cv_malloc_sizeof_addr}" = "${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}"; then
278	AC_MSG_RESULT( (cached) yes)
279	else
280	AC_TRY_RUN([
281	#include "$OM_MALLOC_HEADER"
282	#ifdef OM_HAVE_MALLOC_SOURCE
283	#include "$OM_MALLOC_SOURCE"
284	#endif
285
286	main()
287	{
288	void* addr = OM_MALLOC_MALLOC(512);
289	if (OM_MALLOC_SIZEOF_ADDR(addr) < 512)
290	exit(1);
291	exit(0);
292	}
293	], ac_cv_malloc_sizeof_addr="${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}", ac_cv_malloc_sizeof_addr=no, ac_cv_malloc_sizeof_addr=no)
294	if test "${ac_cv_malloc_sizeof_addr}" = no; then
295	AC_MSG_RESULT(no)
296	else
297	AC_MSG_RESULT(yes)
298	fi
299	fi
300	if test "$ac_cv_malloc_sizeof_addr" != no; then
301	AC_DEFINE(OM_MALLOC_PROVIDES_SIZEOF_ADDR)
302	fi
303
304	if test "${with_provide_malloc}" = malloc; then
305	AC_DEFINE(OM_PROVIDE_MALLOC, 3)
306	elif test "${with_provide_malloc}" = debug; then
307	AC_DEFINE(OM_PROVIDE_MALLOC, 2)
308	elif test "${with_provide_malloc}" = yes; then
309	AC_DEFINE(OM_PROVIDE_MALLOC, 1)
310	else
311	AC_DEFINE(OM_PROVIDE_MALLOC, 0)
312	fi
313
314	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
315	dnl check whether valloc is provided and that it works
316	dnl
317	AC_MSG_CHECKING(whether working valloc exists)
318	if test "${ac_cv_working_valloc}" = no; then
319	AC_MSG_RESULT( (cached) no)
320	elif test "${ac_cv_working_valloc}" = "${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}"; then
321	AC_MSG_RESULT( (cached) yes)
322	else
323	AC_TRY_RUN([
324	#include "$OM_MALLOC_HEADER"
325	#ifdef OM_HAVE_MALLOC_SOURCE
326	#include "$OM_MALLOC_SOURCE"
327	#endif
328
329	main()
330	{
331	void* addr = OM_MALLOC_VALLOC(128*${ac_cv_pagesize});
332	if (addr == 0 \|\| ((unsigned long) addr % ${ac_cv_pagesize}))
333	exit(1);
334	OM_MALLOC_VFREE(addr, 128*${ac_cv_pagesize});
335	exit(0);
336	}
337	], ac_cv_working_valloc="${OM_MALLOC_HEADER}_${OM_MALLOC_SOURCE}", ac_cv_working_valloc=no, ac_cv_working_valloc=no)
338	if test "${ac_cv_working_valloc}" = no; then
339	AC_MSG_RESULT(no)
340	else
341	AC_MSG_RESULT(yes)
342	fi
343	fi
344
345	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
346	dnl for valloc
347	dnl
348	AC_MSG_CHECKING(which valloc to use)
349	if test "${with_valloc+set}" != set \|\| test "${with_valloc}" = mmap; then
350	if test "${ac_cv_working_mmap}" = yes; then
351	with_valloc=mmap
352	AC_DEFINE(OM_HAVE_VALLOC_MMAP)
353	else
354	with_valloc=malloc
355	fi
356	fi
357	if test "${with_valloc}" = malloc; then
358	if test "${ac_cv_working_valloc}" != no; then
359	AC_DEFINE(OM_HAVE_VALLOC_MALLOC)
360	else
361	with_valloc=emulate
362	fi
363	fi
364	AC_MSG_RESULT($with_valloc)
365
366	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
367	dnl emulation
368	dnl
369	AC_MSG_CHECKING(whether to emulate omalloc)
370	if test "${with_emulate_omalloc}" = yes; then
371	AC_DEFINE(OM_EMULATE_OMALLOC)
372	AC_MSG_RESULT(yes)
373	else
374	AC_MSG_RESULT(no)
375	fi
376
377	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
378	dnl alignment
379	dnl
380	AC_MSG_CHECKING(how to align)
381	if test "$with_align" = 8 \|\| test "$ac_cv_sizeof_long" = 8; then
382	ac_cv_align=8
383	AC_DEFINE(OM_ALIGN_8)
384	else
385	if test "$ac_cv_align_need_strict" = "yes" \|\| test "$with_align" = "strict"; then
386	AC_DEFINE(OM_ALIGNMENT_NEEDS_WORK)
387	ac_cv_align="strict"
388	else
389	ac_cv_align="sloppy"
390	fi
391	fi
392	AC_MSG_RESULT($ac_cv_align)
393
394	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
395	dnl dense bins
396	dnl
397	AC_MSG_CHECKING(whether to use dense bins)
398	if test "$with_dense_bins" = yes; then
399	AC_MSG_RESULT(yes)
400	AC_DEFINE(OM_HAVE_DENSE_BIN_DISTRIBUTION)
401	else
402	AC_MSG_RESULT(no)
403	fi
404
405	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
406	dnl debug and inline
407	dnl
408	AC_MSG_CHECKING(whether to disable debugging)
409	if test "$with_debug" != no; then
410	AC_MSG_RESULT(no)
411	else
412	AC_MSG_RESULT(yes)
413	AC_DEFINE(OM_NDEBUG)
414	with_track=no
415	fi
416
417	AC_MSG_CHECKING(whether to have tracking debug functionality)
418	if test "$with_track" != no; then
419	AC_MSG_RESULT(yes)
420	AC_DEFINE(OM_HAVE_TRACK)
421	else
422	AC_MSG_RESULT(no)
423	fi
424
425	AC_MSG_CHECKING(whether to use internal debug)
426	if test "$with_internal_debug" = yes; then
427	AC_MSG_RESULT(yes)
428	AC_DEFINE(OM_INTERNAL_DEBUG)
429	with_inline=no
430	else
431	AC_MSG_RESULT(no)
432	fi
433
434	AC_MSG_CHECKING(whether to inline)
435	if test "$ac_cv_c_inline" != no && test "$with_inline" != no; then
436	AC_DEFINE_UNQUOTED(OM_INLINE, static $ac_cv_c_inline)
437	AC_DEFINE_UNQUOTED(OM_INLINE_DECL, static $ac_cv_c_inline)
438	AC_DEFINE_UNQUOTED(OM_INLINE_IMPL, static $ac_cv_c_inline)
439	AC_DEFINE_UNQUOTED(OM_INLINE_LOCAL, static $ac_cv_c_inline)
440	AC_MSG_RESULT(yes)
441	else
442	AC_DEFINE_UNQUOTED(OM_INLINE_DECL, extern)
443	AC_DEFINE_UNQUOTED(OM_INLINE_IMPL,)
444	AC_DEFINE_UNQUOTED(OM_INLINE_LOCAL, static)
445	AC_MSG_RESULT(no)
446	fi
447
448	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
449	dnl backtrace business
450	dnl
451	AC_MSG_CHECKING(whether GET_RET_ADDR works)
452	AC_CACHE_VAL(ac_cv_get_return_addr_works,
453	AC_TRY_RUN([
454	#include "omReturn.h"
455	int test_return_addr()
456	{
457	char* f;
458	GET_RET_ADDR(f);
459	return (int) f;
460	}
461	int main()
462	{
463	exit(! test_return_addr());
464	}
465	], ac_cv_get_return_addr_works=yes,
466	ac_cv_get_return_addr_works=no,
467	ac_cv_get_return_addr_works=no))
468	AC_MSG_RESULT($ac_cv_get_return_addr_works)
469	if test "$ac_cv_get_return_addr_works" = yes; then
470	AC_DEFINE(OM_GET_RETURN_ADDR_WORKS)
471	fi
472
473	AC_MSG_CHECKING(whether omGetBackTrace works)
474	AC_CACHE_VAL(ac_cv_get_backtrace_works,
475	AC_TRY_RUN([
476	#include "omGetBackTrace.c"
477	#include <stdio.h>
478	int test_backtrace()
479	{
480	void* bt;
481	int i = omGetBackTrace(&bt, 0, 10);
482	return i;
483	}
484	int main()
485	{
486	int i;
487	omInitGetBackTrace();
488	i = test_backtrace();
489	if (i == 1) exit(0);
490	else exit(i+1);
491	}
492	], ac_cv_get_backtrace_works=yes,
493	ac_cv_get_backtrace_works=no,
494	ac_cv_get_backtrace_works=no))
495	AC_MSG_RESULT($ac_cv_get_backtrace_works)
496	if test "$ac_cv_get_backtrace_works" = yes; then
497	AC_DEFINE(OM_GET_BACKTRACE_WORKS)
498	fi
499
500	AC_MSG_CHECKING(whether addr2line works)
501	AC_CACHE_VAL(ac_cv_prog_addr2line_works,
502	AC_TRY_RUN([
503	#undef OM_GET_BACKTRACE_WORKS
504	#include "omReturn.h"
505	#include "omStructs.h"
506	#include "omGetBackTrace.h"
507	#include "omRet2Info.c"
508	#include "omFindExec.c"
509
510
511	int test_Ret_2_Info()
512	{
513	void* bt;
514	int i;
515	struct omRetInfo_s info;
516
517	GET_RET_ADDR(bt);
518	i = omBackTrace_2_RetInfo(&bt, &info, 1);
519	return i;
520	}
521
522	int main(int argc, char** argv)
523	{
524	int i;
525	omInitRet_2_Info(*argv);
526	i = test_Ret_2_Info();
527	if (i==1) exit(0);
528	else exit (i+10);
529	}
530	], ac_cv_prog_addr2line_works=yes,
531	ac_cv_prog_addr2line_works=no,
532	ac_cv_prog_addr2line_works=no))
533	AC_MSG_RESULT($ac_cv_prog_addr2line_works)
534
535	AC_MSG_CHECKING(whether to track return addresses)
536	if test "$with_track_return" = no \|\| test "$ac_cv_get_return_addr_works" = no \|\| test "$ac_cv_prog_addr2line_works" != yes; then
537	with_track_return=no
538	else
539	AC_DEFINE(OM_TRACK_RETURN)
540	with_track_return=yes
541	fi
542	AC_MSG_RESULT($with_track_return)
543
544	AC_MSG_CHECKING(whether to track files and line numbers)
545	if test "$with_track_fl" = no && test "$with_track_return" = no; then
546	with_track_fl=yes
547	fi
548	if test "${with_track_fl+set}" != set; then
549	if test "$with_track_return" = yes; then
550	with_track_fl=no
551	else
552	with_track_fl=yes
553	fi
554	fi
555	AC_MSG_RESULT($with_track_fl)
556	if test "$with_track_fl" = yes; then
557	AC_DEFINE(OM_TRACK_FILE_LINE)
558	fi
559
560	AC_MSG_CHECKING(whether to track stack backtraces)
561	if test "$with_track" != no && test "$ac_cv_get_backtrace_works" = yes && test "$with_track_backtrace" != no && test "$ac_cv_prog_addr2line_works" = yes; then
562	with_track_backtrace=yes
563	AC_DEFINE(OM_TRACK_BACKTRACE)
564	else
565	with_track_backtrace=no
566	fi
567	AC_MSG_RESULT($with_track_backtrace)
568
569	AC_MSG_CHECKING(whether to track custom values)
570	if test "$with_track" != no && test "$with_track_custom" = yes; then
571	AC_DEFINE(OM_TRACK_CUSTOM)
572	else
573	with_track_custom=no
574	fi
575	AC_MSG_RESULT($with_track_custom)
576
577	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
578	dnl figure out the return type of sbrk
579	dnl
580
581	AC_MSG_CHECKING(return type of sbrk)
582	AC_TRY_LINK(
583	#define __USE_MISC
584	#include <unistd.h>
585	,
586	void *sbrk();
587	,
588	AC_DEFINE(Void_t,void),
589	AC_DEFINE(Void_t,char),
590	)
591	AC_MSG_RESULT(Void_t)
592
593
594
595	dnl lllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllll
596	dnl wrap it up
597	dnl
598	AC_CONFIG_HEADER(omConfig.h mylimits.h omMalloc.h:${OM_MALLOC_HEADER})
599
600	AC_OUTPUT(Makefile, \
601	if test "$CONFIG_HEADERS"; then echo timestamp > stamp-h; fi)
602
603

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format