Changeset 2ce040e in git

Timestamp:

Oct 27, 2009, 10:53:18 AM (14 years ago)

Author:

Hans Schönemann <hannes@…>

Branches:

(u'jengelh-datetime', 'ceac47cbc86fe4a15902392bdbb9bd2ae0ea02c6')(u'spielwiese', 'a657104b677b4c461d018cbf3204d72d34ad66a9')

Children:

612c04013d7e4eb721b78e64ea223aa8fa826aaa

Parents:

8af95a22062b8688a1e5b9af457edfb51de44fd9

Message:

*pfister: canomMap


git-svn-id: file:///usr/local/Singular/svn/trunk@12206 2c84dea3-7e68-4137-9b89-c4e89433aadc

File:

• Singular/LIB/homolog.lib (modified) (3 diffs)

Singular/LIB/homolog.lib

@@ -1 +1 @@
 ///////////////////////////////////////////////////////////////////////////////
-version="$Id: homolog.lib,v 1.28 2009-04-07 16:18:05 seelisch Exp $";
+version="$Id: homolog.lib,v 1.29 2009-10-27 09:53:18 Singular Exp $";
 category="Commutative Algebra";
 info="
@@ -9 +9 @@
 
 PROCEDURES:
+ canonMap(id);          the kernel and the cokernel of the canonical map
  cup(M);                cup: Ext^1(M',M') x Ext^1() --> Ext^2()
  cupproduct(M,N,P,p,q); cup: Ext^p(M',N') x Ext^q(N',P') --> Ext^p+q(M',P')
@@ -1867 +1868 @@
 }
 
+proc canonMap(list #)
+"USAGE:  canonMap(id); id= ideal/module,
+RETURN:  a list L, the kernel in two different representations and
+@*       the cokernel of the canonical map
+@*       M ---> Ext^c_R(Ext^c_R(M,R),R) given by presentations
+@*       Here M is the R-module (R=basering) given by the presentation
+@*       defined by id, i.e. M=R/id resp. M=R^n/id
+@*       c is the codimension of M
+@*       L[1] is the preimage of the kernel in R resp. R^n
+@*       L[2] is a presentation of the kernel
+@*       L[3] is a presentation of the cokernel
+EXAMPLE: example canonMap; shows an example
+"
+{
+   module M=#[1];
+   int c=nvars(basering)-dim(std(M));
+   if(c==0)
+   {
+      module K=syz(transpose(M));
+      module Ke=syz(transpose(K));
+      module Co=modulo(syz(transpose(syz(K))),transpose(K));
+    }
+   else
+   {
+      int i;
+      resolution F=mres(M,c+1);
+      module K=syz(transpose(F[c+1]));
+      K=simplify(reduce(K,std(transpose(F[c]))),2);
+      module A=modulo(K,transpose(F[c]));
+      resolution G=nres(A,c+1);
+      for(i=1;i<=c;i++)
+      {
+         K=lift(transpose(F[c-i+1]),K*G[i]);
+      }
+      module Ke=modulo(transpose(K),transpose(G[c]));
+      module Co=modulo(syz(transpose(G[c+1])),transpose(K)+transpose(G[c]));
+   }
+   return(list(prune(Ke),prune(modulo(Ke,M)),prune(Co)));
+
+}
+example
+{ "EXAMPLE:"; echo = 2;
+   ring s=0,(x,y),dp;
+   ideal i = x,y;
+   canonMap(i);
+   ring R = 0,(x,y,z,w),dp;
+   ideal I1 = x,y;
+   ideal I2 = z,w;
+   ideal I = intersect(I1,I2);
+   canonMap(I);
+   module M = syz(I);
+   canonMap(M);
+   ring S = 0,(x,y,z,t),Wp(3,4,5,1);
+   ideal I = x-t3,y-t4,z-t5;
+   ideal J = eliminate(I,t);
+   ring T = 0,(x,y,z),Wp(3,4,5);
+   ideal p = imap(S,J);
+   ideal p2 = p^2;
+   canonMap(p2);
+}
+