Changeset 4508b59 in git for Singular/LIB/ring.lib

Timestamp:

May 18, 2005, 8:07:51 PM (19 years ago)

Author:

Viktor Levandovskyy <levandov@…>

Branches:

(u'spielwiese', 'fe61d9c35bf7c61f2b6cbf1b56e25e2f08d536cc')

Children:

1fdee99658b607d182587d2a784cf9de89f5db6d

Parents:

681d3d8000f4e53193c36f55c66b160df94096f4

Message:

*levandov: procs, moved from noncomm libs


git-svn-id: file:///usr/local/Singular/svn/trunk@8232 2c84dea3-7e68-4137-9b89-c4e89433aadc

File:

• Singular/LIB/ring.lib (modified) (3 diffs)

Singular/LIB/ring.lib

@@ -1 +1 @@
 ///////////////////////////////////////////////////////////////////////////////
-version="$Id: ring.lib,v 1.25 2005-05-06 14:39:08 hannes Exp $";
+version="$Id: ring.lib,v 1.26 2005-05-18 18:07:51 levandov Exp $";
 category="General purpose";
 info="
@@ -21 +21 @@
  preimageLoc(R,phi,Q)     computes preimage for non-global orderings
              (parameters in square brackets [] are optional)
+ rootofUnity(n);         the minimal polynomial for the n-th primitive root of unity
 ";
 
@@ -863 +864 @@
   nu;
 }
+
+//////////////////////////////////////////////////////////////////////////////
+/* moved here from the nctools.lib */
+///////////////////////////////////////////////////////////////////////////////
+proc rootofUnity(int n)
+"USAGE:  rootofUnity(n); n an integer
+RETURN:  number
+PURPOSE: compute the minimal polynomial for the n-th primitive root of unity
+NOTE: works only in field extensions by one element
+EXAMPLE: example rootofUnity; shows examples
+"
+{
+  if ( npars(basering) !=1 )
+  {
+    "the procedure works only with one parameter";
+    return(0);
+  }
+  if (n<1) { return(0); }
+  number mp = par(1);
+  if (n==1) { return(mp-1); }
+  if (n==2) { return(mp+1); }
+  def OldRing = basering;
+  string CH = charstr(basering);
+  string MCH;
+  int j=1;
+  while ( (CH[j] !=",") && (j<=size(CH)))
+  {
+    MCH=MCH+CH[j]; j++;
+  }
+  string SR = "ring @@rR="+MCH+","+parstr(basering)+",dp;";
+  execute(SR);
+  poly @t=var(1)^n-1; // (x^2i-1)=(x^i-1)(x^i+1)
+  list l=factorize(@t);
+  ideal @l=l[1];
+  list @d;
+  int s=size(@l);
+  int d=deg(@l[s]);
+  int cnt=1;
+  poly res;
+  for (j=s-1; j>=1; j--)
+  {
+    if ( deg(@l[j]) > d) { d=deg(@l[j]); }
+  }
+  for (j=1; j<=s; j++)
+  {
+    if ( deg(@l[j]) == d) { @d[cnt]=@l[j]; cnt++; }
+  }
+  if ( size(@d)==1 )
+  {
+    res = poly(@d[1]);
+  }
+  else
+  {
+    j=1;
+    while  ( j <= size(@d) )
+    {
+      res = @d[j]-lead(@d[j]);
+      if ( leadcoef(res) >=0 ) { j++; }
+      else { break; }
+    }
+    res = @d[j];
+  }
+  setring OldRing;
+  poly I = imap(@@rR,res);
+  mp = leadcoef(I);
+  kill @@rR;
+  return(mp);
+}
+example
+{
+  "EXAMPLE:";echo=2;
+  ring r = (0,q),(x,y,z),dp;
+  rootofUnity(6);
+  rootofUnity(7);
+  minpoly = rootofUnity(8);
+  r;
+}