Changeset ec37c7 in git

Timestamp:

May 16, 2019, 2:40:22 PM (5 years ago)

Author:

Andreas Steenpass <steenpass@…>

Branches:

(u'spielwiese', 'fe61d9c35bf7c61f2b6cbf1b56e25e2f08d536cc')

Children:

6c443d2e7ddf6100ffb70f9a46905d75df833663

Parents:

4e5fdad42de8a0a52366ead81619a2e027f2a8ef

git-author:

Andreas Steenpass <steenpass@mathematik.uni-kl.de>2019-05-16 14:40:22+02:00

git-committer:

Andreas Steenpass <steenpass@mathematik.uni-kl.de>2019-05-16 14:46:15+02:00

Message:

add create_ring() to ring.lib

File:

• Singular/LIB/ring.lib (modified) (2 diffs)

Singular/LIB/ring.lib

@@ -41 +41 @@
  addvarsTo(r,vars,i)      add variables to a ring
  addNvarsTo(r,N,name,i)   add N variables to a ring
+ create_ring(l1,l2,l3,l4) return ring(list(l1, l2, l3, l4))
 ";
 
@@ -1334 +1335 @@
   rr;
 }
+
+///////////////////////////////////////////////////////////////////////////////
+//   replacement for ring declarations via execute()
+///////////////////////////////////////////////////////////////////////////////
+
+/*
+ * parses "(v1,v2,v3,v4,v5)" to list("v1", "v2", "v3", "v4", "v5")
+ */
+static proc parse_L2(string l2)
+{
+  list V;
+  int index = 1;
+  int curr = 2;
+  int next = find(l2, ",", curr+1);
+  while (next != 0)
+  {
+    V[index] = l2[curr..(next-1)];
+    index++;
+    curr = next+1;
+    next = find(l2, ",", curr+1);
+  }
+  V[index] = l2[curr..(size(l2)-1)];
+  return(V);
+}
+
+static proc parse_L3(string l3, int n_vars)
+{
+  list L =  list(list(l3, intvec(n_vars)), list("C", intvec(0)));
+  return(L);
+}
+
+proc create_ring(def l1, def l2, def l3, list #)
+"USAGE:  create_ring(l1, l2, l3[, l4, \"no_minpoly\"]);
+         l1 int or list, l2 list or string, l3 list or string, l4 ideal
+RETURN:  ring(list(l1, l2, l3, l4))
+NOTE:    l1, l2, l3, l4 are assumed to be the four entries of ringlist(R)
+         where R is the ring to be returned.
+         @* Optional arguments: If l4 is not given, it is assumend to be
+         ideal(0). If \"no_minpoly\" is given, then the minimal polynomial
+         in l1, if present, is set to 0.
+         @* Shortcuts: Strings such as \"(x,y,z)\" can be given as l2.
+         Indexed variables as in \"(x(1..3),y,z)\" are not supported.
+         Strings representing simple orderings such as \"dp\" or \"lp\" can
+         be given as l3, but more complicated cases such as \"(c,dp)\" are
+         not supported.
+EXAMPLE: example create_ring; shows an example
+"
+{
+  /* setup */
+  list L;
+  int kill_ring;
+  if (!defined(basering))
+  {
+    ring R;
+    kill_ring = 1;
+  }
+
+  /* read optional arguments */
+  ideal l4;
+  int no_minpoly;
+  if (size(#) > 0)
+  {
+    if (typeof(#[1]) == "ideal")
+    {
+      ideal l4 = #[1];
+      # = delete(#, 1);
+    }
+    if (typeof(#[1]) == "string")
+    {
+      if (#[1] == "no_minpoly")
+      {
+        no_minpoly = 1;
+      }
+    }
+  }
+
+  /* L[1] */
+  if (no_minpoly)
+  {
+    if (typeof(l1) == "list")
+    {
+      if (size(l1) == 4)
+      {
+        if (typeof(l1[4]) == "ideal")
+        {
+          l1[4] = ideal(0);
+        }
+      }
+    }
+  }
+  L[1] = l1;
+
+  /* L[2] */
+  if (typeof(l2) == "list")
+  {
+    L[2] = l2;
+  }
+  else
+  {
+    L[2] = parse_L2(l2);
+  }
+
+  /* L[3] */
+  if (typeof(l3) == "list")
+  {
+    L[3] = l3;
+  }
+  else
+  {
+    L[3] = parse_L3(l3, size(L[2]));
+  }
+
+  /* L[4] */
+  L[4] = l4;
+
+  /* return ring */
+  def S = ring(L);
+  if (kill_ring)
+  {
+    kill(R);
+  }
+  return(S);
+}
+example
+{
+  "EXAMPLE:"; echo = 2;
+  ring R = (0,a), x, lp;
+  minpoly = a^2+1;
+  qring Q = ideal(x^3-2);
+  ring S = create_ring(ringlist(Q)[1], "(x,y,t)", "dp", "no_minpoly");
+  basering;
+}